Erro Ao Enviar E-mail

[ADL]

Olá pessoal estou fazendo um script para envio de email aparentemente a página não da erro. mas o email não chega eu fui na pasta BADMAIL e eles estavam lá e verifiquei que tem uma mensagem de erro.

Segue o erro

Não é possível entregar esta mensagem porque ocorreu o seguinte erro: "Erro ao processar o arquivo na pasta de caixa de correio.".

O código de erro específico era 0xC00402CE.

pessoal já revirei o google e nenhuma informação me ajudou, percebi também que muita gente tem dificuldade ne asunto se alguém puder postar alguma coisa eu agradeço muito desde já ADL.

Já registrei a dll do CDONTS também

<%@LANGUAGE="VBSCRIPT"%>
<%
Option explicit
%>
<!--#Include file="conexao1/conexao.inc"-->
<%
response.expires=0
dim estilo,conexaoDataBase,ConnString,rsTabela,sqlTabela,dia,hora,msgTexto,nome,email




Call abreConexao
sqlTabela = "Select data,email,nome From reservaLivro"
set rsTabela = conexaoDataBase.execute(sqlTabela)



do while not rsTabela.eof
dia = cdate(rsTabela("data"))+2
nome = rsTabela("nome")
if dia >= date then

msgTexto = "Devolução do Livro" + vbCRLF
msgTexto = msgTexto + "Nome: " + nome + vbCRLF
msgTexto = "Devolução do Livro" + vbCRLF


response.Expires=0
Set email=server.CreateObject("CDONTS.NewMail")
email.from= "meuemail@meuemail.com.br"
email.to= "fulano@fulano.com.br" 
email.Subject="devolva o livro"
email.Body=msgTexto
email.Send
Set email=nothing


end if

rsTabela.movenext
loop



Call fechaConexao
set rsTabela = nothing
%>

Editado Maio 23, 2007 por andreia_sp
utilize tags para codigos, facilita a visualização. Andreia_Sp

[webdeveloper]

No meu caso também ocorria um erro, não era o mesmo que o seu, porém com o código abaixo funcionou normalmente.

<%
Set objCDOSYSMail = Server.CreateObject("CDO.Message")
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.seuservidor.com.br"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30
objCDOSYSCon.Fields.Update

Set objCDOSYSMail.Configuration = objCDOSYSCon
objCDOSYSMail.From = remetente
objCDOSYSMail.To = destinatario
objCDOSYSMail.CC = copiado
objCDOSYSMail.AddAttachment arq
objCDOSYSMail.Subject = "Teste do CDONTS"
objCDOSYSMail.TextBody = "Funcionou!"
objCDOSYSMail.Send

Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing
%>

Fonte: http://forum.imasters.com.br/index.php?sho...st&p=792289

[ADL]

Ok vou teste obrigado pela sua ajuda.

Ok cara valeu funcionou muito obrigado pela sua ajuda