Algoritimo em VisuALG

[Victor Hugo Marques]

Boa Tarde criei este algoritimo, ele deve receber 2 numeros e efetuar as seguintes operações

- Soma

- Subtração

- Multiplicação e Divisão

Porém não consigo colocalo para executar

se alguém puder ajudar segue o script:

algoritmo "semnome"
// Função :
// Autor :
// Data : 10/3/2011
// Seção de Declarações
var
  n1,n2,rst:real
  op:caractere
inicio
// Seção de Comandos
repita
   escreva ("Informe o 1° Numero  : ")
   leia (n1)
   escreva ("Informe o 2° Numero  : ")
   leia (n2)
   escreva ("Informe a Operação +,-,*,/  : ")
   leia (op)

   // Processamento
   escolha op
   caso (op = "+")
      rst <- (n1 + n2)
      escreval ("O Resultado da Operação = ",rst)
   caso (op = "-")
      rst <- (n1 - n2)
      escreval ("O Resultado da Operação = ",rst)
   caso (op = "*")
      rst <- (n1 * n2)
      escreval ("O Resultado da Operação = ",rst)
   caso (op = "/")
      se n2 <> 0 então
         escreval ("Não é Diviel por '0' !")
      senao
         rst <- (n1 / n2)
         escreval ("O Resultado da Operação = ",rst)
      fimse
   outrocaso
      escreval ("Não efetuamos este tipo de operação ! ")
   fimescolha
   escreva ("Deseja Continuar as Operações s/n ? ")
   leia (op)
   se (op <> "s") então
      interrompa
   fimse
   fimrepita
fimalgoritmo

O VisuALG acusa que esperava um expressão do tipo 'CARACTER'. E tem um segundo segundo algorritimo que é o seguinte: Fazer um progama que receba duas notas, calcular e mostras a média aritmética e as seguintes menssamgens: Média Aritimétrica - Menssagem 0,0 até 4,0 - Reprovado 4,1 até 6,9 - Exame 7,0 até 10 - Aprovado o Script:

var
nota1,nota2,media: real
inicio
// Seção de Comandos
escreva ("Informe a nota do 1° Aluno : ")
leia (nota1)
escreva ("Informe a nota do 2° Aluno : ")
leia (nota2)

// Processo
media <- (nota1 + nota2)/2
escolha media
caso (media <= 4)
   escreval ("Reprovado !")
   escreval ("Com média : ",media)
caso (media >= 4.1)
   escreval ("Exame !")
   escreval ("Com média : ",media)
   se (media < 6.9) então
      escreval ("Exame !")
      escreval ("Com média : ",media)
   senao
      escreval ("Aprovado !")
      escreval ("Com média : ",media)
   fimse
fimescolha

o visuALG ta acusando que media n é real

e não esta executando

Obrigado !

Edited October 4, 2011 by Victor Hugo Marques

[Anderson Rochaa]

O primeiro vai ficar assim:

algoritmo "semnome"
// Função :
// Autor :
// Data : 10/3/2011
// Seção de Declarações
var
n1,n2,rst:real
op:caractere
inicio
// Seção de Comandos
repita
   escreva ("Informe o 1° Numero : ")
   leia (n1)
   escreva ("Informe o 2° Numero : ")
   leia (n2)
   escreva ("Informe a Operação +,-,*,/ : ")
   leia (op)

   // Processamento
   escolha op
   caso "+"
      rst <- (n1 + n2)
      escreval ("O Resultado da Operação = ",rst)
   caso "-"
      rst <- (n1 - n2)
      escreval ("O Resultado da Operação = ",rst)
   caso "*"
      rst <- (n1 * n2)
      escreval ("O Resultado da Operação = ",rst)
   caso "/"
      se n2 = 0 então
         escreval ("Não é Divisivel por '0' !")
      senao
         rst <- (n1 / n2)
         escreval ("O Resultado da Operação = ",rst)
      fimse
   outrocaso
      escreval ("Não efetuamos este tipo de operação ! ")
   fimescolha
   escreva ("Deseja Continuar as Operações s/n ? ")
   leia (op)
   se (op <> "s") então
      interrompa
   fimse
   fimrepita
fimalgoritmo

O segundo vou corrigir dps posto pra vc!

Edited October 14, 2011 by Anderson Rochaa

[Anderson Rochaa]

algoritmo "semnome"

var
nota1,nota2,media: real
inicio
// Seção de Comandos
escreva ("Informe a nota do 1° Aluno : ")
leia (nota1)
escreva ("Informe a nota do 2° Aluno : ")
leia (nota2)

// Processo
media <- (nota1 + nota2)/2
se media <= 4 então
   escreval ("Reprovado !")
   escreval ("Com média : ",media)

senao
   se (media >= 4.1) e (media <= 6.9) então
      escreval ("Exame !")
      escreval ("Com média : ",media)

   senao
      escreval ("Aprovado !")
      escreval ("Com média : ",media)

   fimse
fimse
fimalgoritmo

O segundo vai ficar assim!

Qualquer dúvida poste ai que te dou uma força!

Abçs!

Edited October 14, 2011 by Anderson Rochaa

[willas]

eu estou passando um aperto para resolver um trabalho de faculdade da unopar, que uma das questões é o seguinte:

joão papo de pescador comprou um micro processador para controlar o rendimento diário de seu trabalho, toda vez que ele traz um peso de peixes maior do que o padrão estabelecido, que é 50, ele paga 4 reais de multa por peso excedente. joão precisa que você faça um algoritmo que leia a variável p e verifique se a excesso, se houver gravar na variável e na variável m gravar o valor da multa que joão irá pagar. caso contrario mostrar tais variáveis como 0.

o fluxograma desse problema eu conseguir resolver, não estou conseguindo resolver o pseudocodico, se puder me ajudar eu agradeço.