Duvida recordset

[kassio07]

alguém sabe se tem alguma forma de reutilizar o recordset? pois tenho uma consulta que depois gera uma atualização e gostaria que ela rodasse várias vezes pois ela deve ser feita para todos os registros do meu banco access...

[kassio07]

alguém sabe se tem alguma forma de reutilizar o recordset? pois tenho uma consulta que depois gera uma atualização e gostaria que ela rodasse várias vezes pois ela deve ser feita para todos os registros do meu banco access...

um.Close
        dois.Close
        Set um = Nothing
        Set dois = Nothing
        Sql = ""

[Iceguy]

Continuar com ela aberta assim?

Option Compare Database
Option Explicit

Dim rs As Recordset

Public Sub PrintAndGoForward()

    If rs.BOF Then
        rs.MoveNext
    End If
        
    If Not rs.EOF Then
        Debug.Print rs.Fields("Nome")
        rs.MoveNext
    Else
        Debug.Print "Fim da Recordset."
    End If

End Sub

Public Sub PrintAndGoBackward()

    If rs.EOF Then
        rs.MovePrevious
    End If
    
    If Not rs.BOF Then
        Debug.Print rs.Fields("Nome")
        rs.MovePrevious
    Else
        Debug.Print "Início da Recordset."
    End If

End Sub

Private Function EmptyRecordset() As Boolean

    EmptyRecordset = False
    
    If rs.EOF And rs.BOF Then
        Debug.Print "Recordset vazia."
        EmptyRecordset = True
    End If

End Function

Public Sub UnloadRecordset()

    rs.Close
    Set rs = Nothing
    
    Debug.Print "Recordset descarregado."

End Sub

Public Sub LoadRecordset()

    Set rs = CurrentDb().OpenRecordset("SELECT Tabela1.Nome FROM Tabela1")
    
    If EmptyRecordset Then
        Call UnloadRecordset
    Else
        rs.MoveFirst
        Debug.Print "Recordset inicializado."
    End If

End Sub

Ou reutilizar ela pra outra consulta? Se for é só dar um rs.Close e depois dar um OpenRecordset dnovo

Edited January 31, 2013 by Iceguy