Texto não aparece no DataReport

[Gabriel Cabral]

Olá pessoas...

Na Section2 do DataReport, tenho uma label chamada lblPeriodo....

Nela, quero especificar o período em que será gerado o relatorio...

no botão que gera o relatorio, coloquei o seguinte:

Dim DInicial As Date
Dim DFinal As Date
DInicial = txtDataInicial.Text
DFinal = txtDataFinal.Text
rptConPData.Sections("Section2").Controls("lblPeriodo").Caption = "Período de Referência: " & Format(DInicial, "DD/MM/YYYY") & " a " & Format(DFinal, "DD/MM/YYYY")

As datas serão escolhidas pelo usuário...

Mas isso não está aparecendo no relatorio....não dá erro nenhum, simplesmente não aparece...

já verifiquei..o Visible = True

Quando eu fazia o relatório no DataReport vinculado ao Data Environment, isso dava certo, mas agora que estou fazendo tudo com código, não está.

alguém sabe como fazer aparecer no relatorio??

Obrigado

[Macêdo]

Manda o codigo completo do relatorio

[Gabriel Cabral]

No General Declarations

Public Conex As ADODB.Connection
Public StringDeConexao As String

Dim cmd_relatorio As New ADODB.Command
Dim rs_relatorio As New ADODB.Recordset

No Load do form em que o usuário digita as duas datas

Private Sub Form_Load()
StringDeConexao = "Provider=microsoft.jet.oledb.4.0;" & "Data Source=" & App.Path & "\FinanWin.mdb;"
End Sub

No evento Click do botão que gera o relatorio

Private Sub cmdRelConPData_Click()

If txtDataInicial.Text = "" Then
MsgBox "Preencha a Data Inicial.", vbExclamation
txtDataInicial.SetFocus
ElseIf txtDataFinal.Text = "" Then
MsgBox "Preencha a Data Final.", vbExclamation
txtDataFinal.SetFocus
Else

Dim Conex As New ADODB.Connection
Conex.Open StringDeConexao

With cmd_relatorio
.ActiveConnection = Conex
.CommandType = adCmdText
.CommandText = "SELECT * FROM FinanWin_Contas WHERE isNull(Con_ValorPgtoCP) AND Con_Tipo = 'CP' AND Con_Venc BETWEEN #" & txtDataInicial & "# AND #" & txtDataFinal & "# ORDER BY Con_Venc"
Set rs_relatorio = .Execute
End With

With rptConPData
    Set .DataSource = rs_relatorio
    .DataMember = ""
    .Refresh
    .Show
End With

Dim DInicial As Date
Dim DFinal As Date
DInicial = txtDataInicial.Text
DFinal = txtDataFinal.Text
rptConPData.Sections("Section2").Controls("lblPeriodo").Caption = "Período de Referência: " & Format(DInicial, "DD/MM/YYYY") & " a  " & Format(DFinal, "DD/MM/YYYY")

End If

End Sub

Inclusive foi num tutorial que você postou aqui que eu aprendi usar o DataReport sem DataEnvironment

[Macêdo]

Rapa, olha só, vê se não faz sentido, primeiro você colocou o codigo que gera e abre o relatorio pra depois colocar o codigo que informa o campo da data, inverte a ordem que acho que vai ficar tudo certo

Private Sub cmdRelConPData_Click()

If txtDataInicial.Text = "" Then
MsgBox "Preencha a Data Inicial.", vbExclamation
txtDataInicial.SetFocus
ElseIf txtDataFinal.Text = "" Then
MsgBox "Preencha a Data Final.", vbExclamation
txtDataFinal.SetFocus
Else

Dim Conex As New ADODB.Connection
Conex.Open StringDeConexao

With cmd_relatorio
.ActiveConnection = Conex
.CommandType = adCmdText
.CommandText = "SELECT * FROM FinanWin_Contas WHERE isNull(Con_ValorPgtoCP) AND Con_Tipo = 'CP' AND Con_Venc BETWEEN #" & txtDataInicial & "# AND #" & txtDataFinal & "# ORDER BY Con_Venc"
Set rs_relatorio = .Execute
End With

Dim DInicial As Date
Dim DFinal As Date
DInicial = txtDataInicial.Text
DFinal = txtDataFinal.Text
rptConPData.Sections("Section2").Controls("lblPeriodo").Caption = "Período de Referência: " & Format(DInicial, "DD/MM/YYYY") & " a  " & Format(DFinal, "DD/MM/YYYY")

With rptConPData
    Set .DataSource = rs_relatorio
    .DataMember = ""
    .Refresh
    .Show
End With

End If

End Sub

[Gabriel Cabral]

Tem razão, Macêdo....faz muito sentido

Inverti aqui e deu tudo certo

Muito obrigado