(Resolvido) Muda envio de e-mail CDONTS para CDOSYS

[manogaucho]

Tudo bem!

Tenho este codigo em asp.

Ele serve para, mandar um e-mail de confirmação para o usuario, na finalização do cadastro ou pedido, abaixo esta o codigo.

Set EnvioEmail = Server.CreateObject("CDONTS.NewMail")                
                        EnvioEmail.From = Titulo & "<" & EmailPadrao & ">"
                        EnvioEmail.To = objCliente("Email")
                        EnvioEmail.BodyFormat = 0
                        EnvioEmail.MailFormat = 0
                        EnvioEmail.Subject = "Confirmação de inserção de anúncio."
                        EnvioEmail.Body = VarConfEmail
                        EnvioEmail.Send                
                    Set EnvioEmail = Nothing
                    
                Response.Write "<tr><td align='center' class='TituloVermelho'>Você acaba de receber um e-mail de confirmação.<br>Para que possa ativar seu an&uacute;ncio, entre no mesmo e acesse o link!</td></tr>"

So que meu servidor ( UOL ) Suporta Componente CDOSYS fiz umas mudanças, e ficou assim.

Dim EnvioEmail
                    
                    Set EnvioEmail = Server.CreateObject("CDO.Message")                
                        EnvioEmail.From = Titulo & "<" & EmailPadrao & ">"
                        EnvioEmail.To = objCliente("Email")
                        EnvioEmail.Subject = "Confirmação de inserção de anúncio."                
                    Set EnvioEmail = Nothing
                    
                Response.Write "<tr><td align='center' class='TituloVermelho'>Você acaba de receber um e-mail de confirmação.<br>Para que possa ativar seu an&uacute;ncio, entre no mesmo e acesse o link!</td></tr>"

Agora ele mostra a mensagem "Você acaba de receber um e-mail de confirmação.", o cadastro ou pedido entra no banco de dados, mas não envia E-mail para o usuario. Queria uma ajuda para este novo problema. abaixo esta o codigo todo do arquivo "InsAnuncio.asp" como baixei da internet

<!-- #include file="Includes/BarraCima.asp" -->
<!--#include file="Includes/Form2.asp"-->
<!-- #include file="Includes/Upload.asp" -->
<%
Dim VarAct
Dim objSecoes
Dim objPlanos
Dim VarCodAutenticacao

Set objSecoes = Conn.Execute("SELECT * FROM Secoes ORDER BY Secao")
Set objPlanos = Conn.Execute("SELECT * FROM Planos ORDER BY Cod")

VarAct = Request.QueryString("Act")
VarCodAutenticacao = GerarChave(06)

Dim objEstados2
Set objEstados2 = Conn.Execute("Select * from Estados order by Estado asc")
%>
<script LANGUAGE="Javascript">
<!--
//
function MM_openBrWindow(theURL,winName,features) { //v2.0
  window.open(theURL,winName,features);
}
//-->
</SCRIPT>
  <tr>
    <td valign="top">
    <table width="100%" height="100%" border="0" cellpadding="0" cellspacing="0">
      <tr>
        <td width="150" align="center" valign="top" bgcolor="#F9F9F9"><!-- #include file="Includes/BarraEsq.asp" --></td>
        <td align="center" valign="top" bgcolor="#FFFFFF">
          <table width="468" border="0" cellspacing="0" cellpadding="0">
          <tr>
            <td height="10"><img src="Imagens/Blank.gif" width="1" height="1"></td>
          </tr>
          <tr>
            <td align="center" class="TituloCinzaMedio">INSER&Ccedil;&Atilde;O DE AN&Uacute;NCIO </td>
          </tr>
          <tr>
            <td align="center">&nbsp;</td>
          </tr>
          <tr>
            <td align="center">
            <%
            Dim VarNomeProduto
            Dim VarBreveDescricao
            Dim VarDescricao
            Dim VarValor
            Dim VarFormaPagamento
            Dim VarEstado
            Dim VarCidade
            Dim VarSecao
            Dim VarPlano
            Dim VarLocal
            Dim VarFoto
            Dim VarFoto1
            Dim VarFoto2
            Dim VarFoto3
            Dim VarFoto4
            Dim VarFoto5
            Dim Foto1
            Dim Foto2
            Dim Foto3
            Dim Foto4
            Dim Foto5
            Dim VarMesPagamento
            Dim InsBd
            Dim x
        
            If VarAct = "Cadastrar" Then
            
                '-------------------------------------------------------------                    
                Dim Uploader, File
                Set Uploader = New FileUploader

                Uploader.Upload()
                    
                If Uploader.Files.Count > 0 Then
                    For Each File In Uploader.Files.Items
                        File.SaveToDisk CaminhoFoto
                        VarFoto = VarFoto &"|"& File.FileName
                    Next
                VarFoto = Right(VarFoto, Len(VarFoto)-1)
                VarFoto = Split(VarFoto, "|")
                End If
                    
                VarNomeProduto = Replace(Uploader.Form("NomeProduto"),"'","''")
                VarBreveDescricao = Replace(Uploader.Form("BreveDescricao"),"'","''")
                VarDescricao = Replace(Replace(Uploader.Form("Descricao"),vb script:this.value=''" value="Digite uma cidade" size="1"><span class='TextoCinzaMascara'> (Ex: Mogi das Cruzes)</span></td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td class="TituloCinzaEscuro">Se&ccedil;&atilde;o:*</td>
                <td>
                  <select name="Secao" size="1" class="Form13319">
                    <option selected value="">Selecione a se&ccedil;&atilde;o</option>
                    <%
                    While not objSecoes.EOF
                        Response.Write "<option value='"& objSecoes("Cod") &"'>"& objSecoes("Secao") &"</option>"
                    objSecoes.MoveNext : Wend                        
                    %>
                </select>
                </td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td height="20" colspan="2" align="center" class="TituloCinzaEscuro">&nbsp;</td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td height="20" colspan="2" align="center" class="TituloCinzaEscuro" bgcolor="#DDDDDD">Fotos</td>
                </tr>
                <%
                With Response
                    .Write LinhaHorizontal
                    .Write FCampos(6)
                    .Write LinhaHorizontal
                    .Write FCampos(7)
                    .Write LinhaHorizontal
                    .Write FCampos(8)
                    .Write LinhaHorizontal
                    .Write FCampos(9)
                    .Write LinhaHorizontal
                    .Write FCampos(10)
                    .Write LinhaHorizontal
                End With
                %>
                <tr>
                  <td height="20" colspan="2" align="center" class="TituloCinzaEscuro">&nbsp;</td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td height="20" colspan="2" align="center" class="TituloCinzaEscuro" bgcolor="#DDDDDD">Plano</td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td height="20" colspan="2" align="center">
                      <select name="Plano" class="Form17019">
                      <option selected>Selecione o plano</option>
                      <%
                      While not objPlanos.EOF
                      Response.Write "<option value='"& objPlanos("Cod") &"'>"& objPlanos("Plano")&"</option>"
                      objPlanos.MoveNext
                      Wend
                      %>
                    </select>&nbsp;<a href="#" class="TextoCinzaEscuro" onClick="MM_openBrWindow('PopPlanos.asp','','scrollbars=yes,width=600,height=300')">Conhe&ccedil;a nossos planos</a>
                  </td>
                </tr>
                <%=LinhaHorizontal%>
                <tr>
                  <td height="20" colspan="2" align="center" class="TituloCinzaEscuro">&nbsp;</td>
                </tr>
                <%
                With Response
                    .Write FCampos(11)
                End With
                %>
                <tr>
                    <td height="30" colspan="2" align="center" valign="bottom"><%=Voltar%></td>
                </tr>
              </form>
            </table>
            <% End If %>
            </td>
          </tr>
        </table>
        </td>
        <td width="150" align="center" valign="top" bgcolor="#F8F8F8"><!-- #include file="Includes/BarraDir.asp" --></td>
      </tr>
    </table>
    </td>
  </tr>
<!-- #include file="Includes/Rodape.asp" -->

Agradeço a ajuda, se precisar de mais algum arquivo eu mando ou post aqui. Abraços!!!!

[Rafael Spilki]

Segue um tuto pra usar cdo.sys!

'Criar o objeto para o envio de e-mail
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

'Criar o objeto para configuração do SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

'SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost"

'Porta do SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 27

'Porta do CDO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Timeout
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

objCDOSYSCon.Fields.update

'Atualizar a configuração do CDOSYS para o envio do e-mail
Set objCDOSYSMail.Configuration = objCDOSYSCon

'E-mail do remetente
'Formato: nome <e-mail@meudominio> ou somente o e-mail
objCDOSYSMail.From = "Meu nome <remetente@meudominio.com.br>"

'E-mail do destinatário
'Formato: nome <e-mail@dominio> ou somente o e-mail
objCDOSYSMail.To = "Nome do destinatário <destinatario@dominio.com.br>"

'Anexar um arquivo do seu espaço de hospedagem (opcional). Substitua "pasta" pelo diretório do arquivo
'objCDOSYSMail.AddAttachment("c:\domains\meudominio.com.br\pasta\anexo.jpg")

'Anexar um arquivo que esta em uma URL (opcional)
'objCDOSYSMail.AddAttachment "http://www.meudominio.com.br/pasta/nome_arquivo.jpg"

'Assunto da mensagem
objCDOSYSMail.Subject = "Teste do componente CDOSYS"

'Conteúdo da mensagem
objCDOSYSMail.TextBody = "Teste do componente CDOSYS"
'para envio da mensagem no formato html altere o TextBody para HtmlBody
'objCDOSYSMail.HtmlBody = "Teste do componente CDOSYS"

'objCDOSYSMail.fields.update
'Enviar o e-mail
objCDOSYSMail.Send

'Destruir os objetos
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

response.write "E-mail enviado para destinatario@dominio.com.br"

[]'s Rafael Spilki

[manogaucho]

Tudo bem, fiz todas as mudanças possiveis nesta semana mas não deu certo, já não sei o que fazer.

Mandei um E-mail para o pessoal da UOL sobre este assunto e eles me responderam assim:

Para envio de e-mails através do site, é necessária a utilização de SMTP autenticado. Ou seja, você terá de implementar em seu código, a autenticação no momento do envio.

Abaixo, indicamos uma FAQ de exemplo da utilização do componente CDOSYS:

http://tutorial.uolhost.com.br/index.php?i...sta&res=505

Lembramos que para esta autenticação, você deve utilizar uma conta do seu domínio e sua respectiva senha, assim como o seu servidor smtp, que seria:

stmp.meudominio.dominiotemporario.com

Acho que pode ajudar.

Editado Março 21, 2009 por manogaucho

[manogaucho]

Fiz umas mudanças e deu certo, com a ajuda do "Rafael Spilki" e de outros amigos ficou assim a mudança

sch = "http://schemas.microsoft.com/cdo/configuration/"
Set cdoConfig = Server.CreateObject("CDO.Configuration")

cdoConfig.Fields.Item(sch & "sendusing") = 2
cdoConfig.Fields.Item(sch & "smtpauthenticate") = 1
cdoConfig.Fields.Item(sch & "smtpserver") = "smtp.SEU_DOMINIO_TEMPORARIO" 'Informe o domínio do seu painel de controle.
cdoConfig.Fields.Item(sch & "smtpserverport") = 25
cdoConfig.Fields.Item(sch & "smtpconnectiontimeout") = 30
cdoConfig.Fields.Item(sch & "sendusername") = "CONTA DE E-MAIL VÁLIDA PARA AUTENTICAR" 'conta@seu_dominio
cdoConfig.Fields.Item(sch & "sendpassword") = "SENHA DO E-MAIL"
cdoConfig.fields.update

Set cdoMessage = Server.CreateObject("CDO.Message")
Set cdoMessage.Configuration = cdoConfig

cdoMessage.From = "conta@seu_dominio" 'ENDEREÇO DE E-MAIL QUE SERÁ EXIBIDO NO FROM DA MENSAGEM
cdoMessage.To = objCliente("Email")
cdoMessage.Subject = "Confirmação de inserção de anúncio."
cdoMessage.ReplyTo = objCliente("Email")
cdoMessage.HTMLBody = VarConfEmail
cdoMessage.Send

Set cdoMessage = Nothing
Set cdoConfig = Nothing

response.write "O e-mail foi processado e enviado com sucesso"
%>