Ir para conteúdo
Fórum Script Brasil
  • 0

Fotos Aleatórias Na Home Page, Relacionada Aos Ultimos Eventos

AMON-HÁ

Perguntado por AMON-HÁ,

 Share

Pergunta

AMON-HÁ

AMON-HÁ

Postado
Postado

Pessoal,

eu estou meio enferrujado em ASP daí que eu estou com problema na construção de um script aqui...

bom...

eu quero exatamente algo do tipo... que seja mostradas fotos relacionadas aos 5 ultimos eventos na página principal do site...

essas fotos seram pegas das pastas aonde contem as fotos em miniatura... até aí tudo bem...

só que eu queria que essas fotos fossem pegas de forma aleatórias...

veja um exemplo na imagem abaixo:

http://img205.imageshack.us/img205/3922/modelo4ll.gif

outra coisa...

uma forma que eu estou usando para pegar as fotos é a seguinte:

Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Set PASTA = FSO.Getfolder("C:\Inetpub\wwwroot\fotos\thumbnails\")
Set Arquivos = PASTA.Files

FOR EACH foto IN Arquivos
    If FSO.GetExtensionName(foto.name) = "jpg" Then
        Response.Write "<img border=""0"" rc=""thumbnails/" & foto.name & """ width=""80"" height=""60"">"
        EXIT FOR
    End If
NEXT

teria por acaso uma forma mais prática???

eu não conseguir pensar em nada diferente...

vlw por que puder dar uma opnião aí...

Link para o comentário
Compartilhar em outros sites

4 respostass a esta questão

Posts Recomendados

  • 0
DataSet

DataSet

Postado
Postado

Para pegar as fotos, você pode gravar o caminho dela numa tabela do banco, daí fazendo um select nessa coluna, você vai ter

response.write "<td><img src="&tabFot("nomCam")&"></td>"

Faça o select para pegar o caminho da foto e use o comando 'random' para randomizar e pegar aleatoriamente.

Link para o comentário
Compartilhar em outros sites
  • 0
AMON-HÁ

AMON-HÁ

Postado
  • Autor
Postado

Para pegar as fotos, você pode gravar o caminho dela numa tabela do banco, daí fazendo um select nessa coluna, você vai ter

response.write "<td><img src="&tabFot("nomCam")&"></td>"

Faça o select para pegar o caminho da foto e use o comando 'random' para randomizar e pegar aleatoriamente.

Olá DataSet,

você está falando em eu colocar no banco de dados o caminho pra cada foto???

é isso??

cara... é muita foto... milhares pra ser mais exato...

não dá pra registrar foto por foto no banco não...

ou melhor... dar até dá... mas fica muito pesado o banco...

prefereria que fizesse um rodomize na hora que pegasse a foto na pasta com o objeto FileSystem... se é que isso é possível não é???

Link para o comentário
Compartilhar em outros sites
  • 0
DataSet

DataSet

Postado
Postado

Crie um arquivo chamado RandomImage.inc

Conteúdo desse arquivo:

<%
  Function RandomImage(strPath,strDefault)
    On Error Resume Next
    Randomize Timer

    Dim objFSO, objFolder, objFiles, objFile
    Dim strFiles, strImages, strPhysical, strFile

    Const strValid = ".gif.jpg.png"

    If Right(strPath,1) <> Chr(47) Then strPath = strPath & Chr(47)
    strPhysical = Server.MapPath(strPath)
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(strPhysical)
    Set objFiles = objFolder.Files

    For Each objFile in objFiles
      strFile = LCase(objFile.Name)
      If Instr(strValid,Right(strFile,4)) Then
        strFiles = strFiles & strFile & vbTab
      End If
    Next

    strImages = Split(strFiles,vbTab)
    
    If UBound(strImages) > 1 Then
      RandomImage = strPath & strImages(Int(Rnd(1)*UBound(strImages)))
    Else
      RandomImage = strDefault
    End If

  End Function
%>
Crie um arquivo chamado randomimages.asp Conteúdo desse arquivo: 
<% @Language="VBScript" %>
<% Option Explicit %>
<html>
<head>
<!--#include virtual="/includes/RandomImage.inc"-->
</head>
<body>
<div align="center"><center>
<table border="1">
  <tr>
    <td bgcolor="#ffffff">
      <img src="<%=RandomImage("/images/","/images/default.gif")%>">
    </td>
  </tr>
</table>
</center></div>
</body>
</html>

Arrume o include virtual de acordo com a estrutura das suas pastas aí

Se você passar o primeiro paramentro na chamada da função, ele vai mostrar as imagem ramdomicamente, se ele não achar nenhuma imagem na pasta, ele mostra a imagem referente ao segundo parametro.

Qualquer coisa tecla aí

Link para o comentário
Compartilhar em outros sites

Participe da discussão

Você pode postar agora e se registrar depois. Se você já tem uma conta, acesse agora para postar com sua conta.

Visitante
Responder esta pergunta...

×   Você colou conteúdo com formatação.   Remover formatação

  Apenas 75 emoticons são permitidos.

×   Seu link foi incorporado automaticamente.   Exibir como um link em vez disso

×   Seu conteúdo anterior foi restaurado.   Limpar Editor

×   Você não pode colar imagens diretamente. Carregar ou inserir imagens do URL.

×
 Share
Ir para lista de Perguntas


  • Estatísticas dos Fóruns

    • Tópicos
      152,3k
    • Posts
      652,3k
×
×
  • Criar Novo...