[resolvido] Paginação > Erro '800a01a8'

[Notax]

Pessoal, olha eu aí denovo... com mais essa dificuldade... já fiz minhas pesquisas em google e aqui no SB mesmo mas não rolou... não consegui desfazer esta outra bronca...

to tentando fazer uma paginação... mas ta dando o erro abaixo:

Microsoft VBScript runtime error '800a01a8'

Object required: ''

line 8

que vem a ser essa linha:

objRs.PageSize = 5

o código completo segue abaixo:

<%
Dim objConn, objRs, strQuery, ComandoSQL, Conexao, SQL, intpagina, intrec
Dim strConnection
Set objConn =  Server.CreateObject("ADODB.Connection")
objConn.Open "DBQ=" & Server.MapPath("bd.mdb") & ";Driver={Microsoft Access Driver (*.mdb)}","username","password"
strQuery = "SELECT * FROM a_pagar"

objRs.PageSize = 5 ' Você pode alterar sem conforme precise
objRs.Open SQL,objConn,3,3

IF onjRs.EOF then 
   Response.Write "nenhum registro encontrado"
   Response.End 'paramos o programa
ELSE

'Definindo em qual pagina o visitante está
   IF Request.QueryString("pagina")="" then 
      intpagina=1 
   ELSE
      IF cint(Request.QueryString("pagina"))<1 then
         intpagina=1 
      ELSE
         IF cint(Request.QueryString("pagina"))> objRs.PageCount then 
            intpagina=objRs.PageCount 
         ELSE
            intpagina=Request.QueryString("pagina")
         END IF
      END IF
   END IF
END IF

objRs.AbsolutePage=intpagina
intrec=0
While intrec < objRs.PageSize and not RS.EOF 

'------------------- AQUI VEM TUDO O QUE SEÁ PAGINADO -----------------------
   response.write objRs("data") & " - " & objRs("historico") & " - " & objRs("tipo") &  " - " & objRs("valor") & "<BR>"
'---------------------------------------------------------------------------------------------
objRs.MoveNext

   intrec=intrec+1 
  
   IF objRs.EOF then 
      response.write " " 
   END IF
Wend

IF intpagina > 1 then 
%> 
   <a href="a_pagar_paginacao.asp?pagina=<%=intpagina-1%>">Anterior</a> 
<% 
END IF
IF strcomp(intpagina,RS.PageCount) <> 0 then 
%> 
   <a href="a_pagar_paginacao.asp?pagina=<%=intpagina + 1%>">Próxima</a> 
<% 
END IF
%>

grato pela atenção

[kuroi]

antes dessa linha, ponha o codigo:

Set objRs =  Server.CreateObject("ADODB.RecordSet")

[Notax]

valeu Kuroi Matou a pau... funcionou legal...

eu é que tinha cometido mais alguns errinhos de digitação depois desse grande erro que o amigo ajudou a corrigir... mas daí ficou fácil de arrumar, pois as mensagens de erros eram bastante características...

Sem a sua ajuda, com certeza ainda estaria travado... valeu mesmo.

segue o código completo para caso alguém encontre uma dificuldade parecida:

<%
Dim objConn, objRs, strQuery, ComandoSQL, Conexao, SQL, intpagina, intrec
Dim strConnection
Set objConn =  Server.CreateObject("ADODB.Connection")
objConn.Open "DBQ=" & Server.MapPath("bd.mdb") & ";Driver={Microsoft Access Driver (*.mdb)}","username","password"
'strQuery = "SELECT * FROM a_pagar"
Set objRs =  Server.CreateObject("ADODB.RecordSet")
objRs.PageSize = 5 ' Você pode alterar sem conforme precise
SQL = "select * from a_pagar"
objRs.Open SQL,objConn,3,3

IF objRs.EOF then 
   Response.Write "nenhum registro encontrado"
   Response.End 'paramos o programa
ELSE

'Definindo em qual pagina o visitante está
   IF Request.QueryString("pagina")="" then 
      intpagina=1 
   ELSE
      IF cint(Request.QueryString("pagina"))<1 then
         intpagina=1 
      ELSE
         IF cint(Request.QueryString("pagina"))> objRs.PageCount then 
            intpagina=objRs.PageCount 
         ELSE
            intpagina=Request.QueryString("pagina")
         END IF
      END IF
   END IF
END IF

objRs.AbsolutePage=intpagina
intrec=0
While intrec < objRs.PageSize and not objRs.EOF 

'------------------- AQUI VEM TUDO O QUE SEÁ PAGINADO -----------------------
   response.write objRs("data") & " - " & objRs("historico") & " - " & objRs("tipo") &  " - " & objRs("valor") & "<BR>"
'---------------------------------------------------------------------------------------------
objRs.MoveNext

   intrec=intrec+1 
  
   IF objRs.EOF then 
      response.write " " 
   END IF
Wend

IF intpagina > 1 then 
%> 
   <a href="a_pagar_paginacao.asp?pagina=<%=intpagina-1%>">Anterior</a> 
<% 
END IF
IF strcomp(intpagina,objRs.PageCount) <> 0 then 
%> 
   <a href="a_pagar_paginacao.asp?pagina=<%=intpagina + 1%>">Próxima</a> 
<% 
END IF
%>