[resolvido] Form em Asp + Flash

[Prof. Jonatas]

galera, alguém sabe me dizer porque não está sendo enviado o email, tem algo de errado com o código ?

<%

'As informações que serão enviadas para você usando objCDOMail

Dim strTo, strSubject, strBody

Dim objCDOMail

'Digite seu e-mail abaixo

strTo = "jonatas.r@begbrasil.com.br"

'Esta área recupra os dados enviados por seu filme como o assunto e a mensagem

strSubject = Request.Form("assunto")

strBody = Request.Form("mensagem")

'Enviando as informações para seu e-mail usando CDONTS.NEWMAIL

Set objCDOMail = Server.CreateObject("CDONTS.NewMail")

'Coloque o titulo do e-mail que você vai receber no lugar de Email Emerson Freecode

objCDOMail.From = "Titulo"

objCDOMail.To = strTo

objCDOMail.Subject = strSubject

objCDOMail.Body = strBody

objCDOMail.Send

Set objCDOMail = Nothing

%>

[Notax]

Amigão, já entrou em contato com seu servidor para saber se tem possibilidade de utilizar o componente cdonts?

Veja que existem basicamente dois componentes para envio de e-mails através de formulários: o cdonts e o cdosys...

Este script que postou está utilizando o cdonts, portanto antes de mais nada precisa confirmar com o servidor qual componente você pode usar, ok?

Depois posta aí o componente que conforme for posto um script pra ti!

notax.

[bareta]

quase isso o cdonts é a versão antiga do cdosys... portanto o cdonts não funciona mais, por enquanto isto basta...

então seguindo isso todos os servidores windows ( os q vi ) usam cdosys...

outra coisa já testou para ver se o form ta passando os campo certinho??? esperimente alterar o componente e testar.

[Notax]

Então tá aí... conforme falado e confirmado por nosso amigo Bareta!

segue portanto conforme prometido um tuto usando o componente cdosys...

faça as alterações necessárias e manda bala!

qualquer. coisa posta aí...

'Criar o objeto para o envio de e-mail
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

'Criar o objeto para configuração do SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

'SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost"

'Porta do SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 25

'Porta do CDO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Timeout
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

objCDOSYSCon.Fields.update

'Atualizar a configuração do CDOSYS para o envio do e-mail
Set objCDOSYSMail.Configuration = objCDOSYSCon

'E-mail do remetente
'Formato: nome <e-mail@meudominio> ou somente o e-mail
objCDOSYSMail.From = "Meu nome <remetente@meudominio.com.br>"

'E-mail do destinatário
'Formato: nome <e-mail@dominio> ou somente o e-mail
objCDOSYSMail.To = "Nome do destinatário <destinatario@dominio.com.br>"

'Anexar um arquivo do seu espaço de hospedagem (opcional). Substitua "pasta" pelo diretório do arquivo
'objCDOSYSMail.AddAttachment("c:\domains\meudominio.com.br\pasta\anexo.jpg")

'Anexar um arquivo que esta em uma URL (opcional)
'objCDOSYSMail.AddAttachment "http://www.meudominio.com.br/pasta/nome_arquivo.jpg"

'Assunto da mensagem
objCDOSYSMail.Subject = "Teste do componente CDOSYS"

'Conteúdo da mensagem
objCDOSYSMail.TextBody = "Teste do componente CDOSYS"
'para envio da mensagem no formato html altere o TextBody para HtmlBody
'objCDOSYSMail.HtmlBody = "Teste do componente CDOSYS"

'objCDOSYSMail.fields.update
'Enviar o e-mail
objCDOSYSMail.Send

'Destruir os objetos
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

response.write "E-mail enviado para destinatario@dominio.com.br"

Notax

[Prof. Jonatas]

VIXI, Obigado pela pronta resposta.

Mas como faço pra adptar o meu código ao seu?

Eu sou leigo em asp, não manjo nada......

Se alguém poder me ajudar segue abaixo meus arquivos "fla" e "asp"

www.magiadobrilho.com.br/teste.zip

Editado Novembro 30, 2007 por Prof. Jonatas

[Notax]

Dei uma olhada aqui nis seus arquivos...

o que está acontecendo??? qual o erro que dá? não dá nada? conta mais...

notax

[Prof. Jonatas]

Então não dá erro nenhum, simplesmente não envai o email....... Eu também não consigo entender !

Coloquei o mesmo ex. em 2 servidores diferentes mas só funciona em um, bem o que nãp precisa funcionar, no correto não funciona, ta a mesma coisa nos dois.

LOCAWEB - Neste funciona - mas o site está hospedado em outro

http://www.begbrasil.com.br/teste/novo.htm

GRUPOLG - O Site está hospedado aqui mas aqui não funciona.

http://www.magiadobrilho.com.br/teste/novo.htm

Vou colocar abaixo o código q eu estou usando para vocês verem:

<%

'

' FLASHMAIL 1.0

'

' Autores:

' Kali Romiglia (http://www.romiglia.com)

' Miguel Mora (http://www.prodigia.com)

' DUDAS O PREGUNTAS A KALI@ROMIGLIA.COM

'

' INSTRUCCIONES ::

'

' Este archivo debe ir en la misma carpeta donde este el swf.

'

' Solo debes cambiar tres variables::

' 1_ Destino = "tuemail@tudominio.com"

' 2_ servidor = "mail.tuservidor.com" si no sabes cual es, simplemente contactate con tu proveedor

' 3_ titulo = "el titulo que aparecerá en el email"

'

'

Destino = "jonatas@studiomais.biz"

servidor = "mail.magiadobrilho.com.br"

titulo = "Formulario de contacto"

'Asignamos los valores recibidos del formulario a las variables

'Estas variables deben estar en el formulario dentro del swf

Origen = Request("email")

nombre = Request("nombre")

empresa = Request("empresa")

Mensaje = Request("mensaje")

'Creamos una instancia del objeto ASPMAIL

Set Mail = Server.CreateObject("Persits.MailSender")

' Creamos el cuerpo del mensaje

strBody = strBody & "<font face='Verdana, Arial, Helvetica, sans-serif' size='2' color='#555555'>"

strBody = strBody & "Mi nombre es: "

strBody = strBody & "<b>" & nombre & "</b><br><br>"

strBody = strBody & "Mi e-mail es: "

strBody = strBody & "<b>" & Origen & "</b><br><br>"

strBody = strBody & "Trabajo en la empresa: "

strBody = strBody & "<b>" & empresa & "</b><br><hr><br>"

strBody = strBody & "Mi mensaje es: <br>"

strBody = strBody & Mensaje & chr(10)

strBody = strBody & "</font>"

'Asignamos las propiedades al objeto con ASPMAIL

Mail.Host = servidor

Mail.Port = 25 ' Valor opcional. 25 es el puerto por defecto.

Mail.From = Origen

Mail.FromName = Email ' Opcional

Mail.Subject = titulo

Mail.Body = strBody

Mail.IsHTML = True

Mail.AddAddress Destino

On Error Resume Next

Mail.Send

' El control del error es con ASPMAIL

If Err <> 0 Then

Response.Write "popup.mensaje=Error, envíelo mas tarde " & Err.Description

Else

Response.Write "popup.mensaje=Mensaje enviado correctamente."

End If

'Destruimos el objeto con aspmail

Set Mail = Nothing

%>

Editado Dezembro 3, 2007 por Prof. Jonatas

[Notax]

aham... tenta assim então e depois posta se deu certo ou o que aconteceu, ok?

<%

'Criar o objeto para o envio de e-mail
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

'Criar o objeto para configuração do SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

'SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "localhost"

'Porta do SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 25

'Porta do CDO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'Timeout
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

objCDOSYSCon.Fields.update

'Atualizar a configuração do CDOSYS para o envio do e-mail
Set objCDOSYSMail.Configuration = objCDOSYSCon

'E-mail do remetente
'Formato: nome <e-mail@meudominio> ou somente o e-mail
objCDOSYSMail.From = request.form = ("email")

'E-mail do destinatário
'Formato: nome <e-mail@dominio> ou somente o e-mail
objCDOSYSMail.To = "Jonatas <jonatas@studiomais.biz>"

'Anexar um arquivo do seu espaço de hospedagem (opcional). Substitua "pasta" pelo diretório do arquivo
'objCDOSYSMail.AddAttachment("c:\domains\meudominio.com.br\pasta\anexo.jpg")

'Anexar um arquivo que esta em uma URL (opcional)
'objCDOSYSMail.AddAttachment "http://www.meudominio.com.br/pasta/nome_arquivo.jpg"

'Assunto da mensagem
objCDOSYSMail.Subject = "Teste do componente CDOSYS"

'Conteúdo da mensagem
objCDOSYSMail.TextBody = request.form("nome") & vbCrLf & request.form = ("conteudo")
'para envio da mensagem no formato html altere o TextBody para HtmlBody
'objCDOSYSMail.HtmlBody = "Teste do componente CDOSYS"

'objCDOSYSMail.fields.update
'Enviar o e-mail
objCDOSYSMail.Send

'Destruir os objetos
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

response.write "E-mail enviado para mim"

%>

[Prof. Jonatas]

Galera gostaria de agradecer aqueles que me ajudaram nesta dúvida, NOTAX, BARETA, muito obrigado pelo apoio viu.

Para quem tem a mesma dúvida q a minha eu consegui solucionar usando o cdosys. :rolleyes:

Vou colocar abaixo o código, brigaduuuuuuuuuuuuu!

<%

'Declaração de Variáveis

Dim nome

Dim email

Dim telefone

Dim coment

Dim mensagem

Dim meuemail

'Captando os dados

nome = Request("nome1")

email = Request("email")

telefone = Request("telefone")

coment = Request("comentario")

'Forma de recebimento no email

mensagem = "Nome: "& nome & vbcrlf

mensagem = mensagem & "E-mail: " & email & vbcrlf

mensagem = mensagem & "Telefone: " & telefone & vbcrlf

mensagem = mensagem & "Comentário: " & vbcrlf

mensagem = mensagem & coment

'Enviando o email

Set meuemail = CreateObject("CDO.Message")

meuemail.From = email

meuemail.To = "magia@magiadobrilho.com.br"

meuemail.Subject = "Contato pelo site."

meuemail.TextBody = mensagem

meuemail.Send

'Condições para feedback no flash

If Err <> 0 Then

Response.Write "janela.mess=Sem conexão com o Servidor " & ", " & "favor tente mais tarde !"

Else

Response.Write "janela.mess=Parabéns " & nome & ", seu email foi enviado com sucesso!"

End If

%>

No Flash

envia.onRelease = function(){

loadVariables("envia.asp", "", "POST");

}

Té mais galera.

Se o Moderador quiser pode fechar, valeu!!!!!!!!! ;)

Editado Dezembro 4, 2007 por Prof. Jonatas