Uma dúvida sobre o Commandbars

[Betocadilhe]

Eu criei um Userform numa planilha da pasta de trabalho Teste.xls. Quero colocar um menu no meu Excel para acessar essa planilha onde tem o meu Userform. Como faço isso? Não quero incluir, por exemplo, este menu dentro do menu Ferramentas, mas no menu principal, ao lado do menu Ferramentas.

Meu código para incluir este menu deve ser escrito aonde? Num módulo em qualquer planilha?

Uso o Excel 2003.

Luiz Roberto

[João.Neto]

Luiz,

Eu tenho essa rotina que eu utilizo para criar um menu ao lado do menu Ajuda, o qual me permite abrir meu formulário.

Ah, eu o coloco em um módulo de código.

Sub AddMenus(ByVal SYS As SISTEMA)

    Dim cMenu1 As CommandBarControl
    Dim cbMainMenuBar As CommandBar
    Dim iHelpMenu As Integer
    Dim cbcCutomMenu As CommandBarControl
        
    On Error Resume Next
    
    Application.CommandBars("Worksheet Menu Bar").Controls("&Sistema BackOffice").Delete
    
    On Error GoTo 0
    
    Set cbMainMenuBar = Application.CommandBars("Worksheet Menu Bar")
    
    iHelpMenu = cbMainMenuBar.Controls("Ajuda").Index
    
    Set cbcCutomMenu = cbMainMenuBar.Controls.Add(Type:=msoControlPopup, Before:=iHelpMenu)

    cbcCutomMenu.Caption = "&Sistema BackOffice"
       
        With cbcCutomMenu.Controls.Add(Type:=msoControlButton)
        .Caption = "&Reexibir Sistema"
        .OnAction = "MyMacro1"
        End With

End Sub

Sub DeleteMenu()

On Error Resume Next

    Application.CommandBars("Worksheet Menu Bar").Controls("&Sistema BackOffice").Delete
    On Error GoTo 0

End Sub

Sub MyMacro1()
    frmBackOffice.Show
End Sub

E esse código aqui eu coloco no EstaPasta_de_trabalho:

Private Sub Workbook_BeforeClose(Cancel As Boolean)

    DeleteMenu
    
End Sub

Private Sub Workbook_Open()
AddMenus
End Sub

Editado Julho 19, 2009 por João.Neto
Adcionar tag's (Jonathan)