arquivo de configuração externo

[Alex Mauricio]

Boa tarde pessoal.

Tenho uma dúvida.

Tenho uma pequena aplicação e gostaria de criar um arquivo externo (configura.ini) onde em cada estação eu possa modificar a configuração para o mesmo localizar o BD.

Tipo. Hoje a configuração do BD é assim:

Set BancoDeDadosAntigo = OpenDatabase("I:\SGCC\Versao_1.0.01\prjSGCC\BD\BANCO.MDB")

Gostaria de passar essa configuração para um ini.

Obrigado.

[Gamaliel]

Public Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Public Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long


Public Function pFncLeArquivoIni(cArquivo As String, cSessao As String, cParametro As String, Optional lVerificaArquivo As Boolean = True) As String
    
    Dim nTamanhoRetorno As Long
    Dim cRetorno        As String

    cRetorno = Space(255)
    cParametro = UCase(cParametro)

    If lVerificaArquivo Then
        If Dir(cArquivo) = "" Then
            pFncLeArquivoIni = ""
            Exit Function
        End If
    End If

    nTamanhoRetorno = GetPrivateProfileString(UCase(cSessao), cParametro, "", cRetorno, Len(cRetorno), cArquivo)
    If nTamanhoRetorno > 0 Then
        cRetorno = Left(cRetorno, nTamanhoRetorno)
        pFncLeArquivoIni = cRetorno
    Else
        pFncLeArquivoIni = ""
    End If
    
End Function

Public Function pFncEscArqIni(cSecao As String, cNomeChave As String, cValor As String, cArquivoINI As String) As Integer

    Dim nRetorno As Integer

    On Error GoTo TrataErro

    nRetorno = WritePrivateProfileString(cSecao, cNomeChave, cValor, cArquivoINI)
    If nRetorno = False Then
        pFncEscArqIni = 1
    End If

    pFncEscArqIni = 0
    Exit Function

TrataErro:
    Err.Clear
    pFncEscArqIni = 2

End Function

Espero te-lo ajudado. :lol:

Editado Novembro 17, 2009 por kuroi
Adicionar tag CODE