Imagem De Menu

[Deborah]

Olá...

Como faço para colocar uma imagem no menu principal de um sistema?

Não vejo nenhum item no VB6 no qual eu possa inserir uma gravura ao lado do texto de uma barra de menu. O que eu faço?

Já grata, Déborah.

[Bicicleta]

Olá Deborah...

Eu utilizo uma .ocx pra fazer isso!!! No próprio VB não tem como!!!

Só que agora eu não tenho a q eu utilizo aqui...

Mais dá uma olhada nesse link aqui, e veja o primeiro ítem da lista...

[]s

[Promotor Advanced]

Você vai ter 4 images como nome de

imOpen

imSave

imPrint

imPrintSetup

imCopy

crie um menu desse jeito

&File

""&Open

""&Save

""-

""&Print

""Print &Setup

&Edit

""&Extra Sub Menu

""""&Copy

Option Explicit

' MenuBmp sample by Matt Hart - mhart@taascforce.com
' http://www.webczar.com/defcon/mh/vbhelp.html
' http://www.webczar.com/defcon/mh
'
' This sample shows you how to add bitmaps to your
' menu items.  First, you must retrieve the VB menu handle
' with the GetMenu API call.  Then, you set the Unchecked and
' Checked bitmaps (I don't differentiate between the two
' with this example - usually you would put a checkmark in
' the bitmap and use that for Checked).
'
' Note that the Picture property of an Image control (or
' a Picture control) is the Bitmap Handle, this the Image
' controls can be used like a bitmap resource.
'
' I also have one sub menu so that you can see how getting
' submenu handles and item positions works.

Private Declare Function GetMenu Lib "user32" _
   (ByVal hwnd As Long) As Long

Private Declare Function GetSubMenu Lib "user32" _
   (ByVal hMenu As Long, ByVal nPos As Long) As Long

Private Declare Function SetMenuItemBitmaps Lib "user32" _
   (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long, _
    ByVal hBitmapUnchecked As Long, ByVal hBitmapChecked As Long) As Long

Const MF_BYPOSITION = &H400&

' VB 5 doesn't need this declration, but VB 4 does.
' Private Declare Function VarPtr Lib "VB40032.DLL" (variable As Any) As Long

Private Sub Form_Load()
    Dim mHandle As Long, lRet As Long, sHandle As Long, sHandle2 As Long
    mHandle = GetMenu(hwnd)
    sHandle = GetSubMenu(mHandle, 0)
    lRet = SetMenuItemBitmaps(sHandle, 0, MF_BYPOSITION, imOpen.Picture, imOpen.Picture)
    lRet = SetMenuItemBitmaps(sHandle, 1, MF_BYPOSITION, imSave.Picture, imSave.Picture)
    lRet = SetMenuItemBitmaps(sHandle, 3, MF_BYPOSITION, imPrint.Picture, imPrint.Picture)
    lRet = SetMenuItemBitmaps(sHandle, 4, MF_BYPOSITION, imPrintSetup.Picture, imPrintSetup.Picture)
    sHandle = GetSubMenu(mHandle, 1)
    sHandle2 = GetSubMenu(sHandle, 0)
    lRet = SetMenuItemBitmaps(sHandle2, 0, MF_BYPOSITION, imCopy.Picture, imCopy.Picture)
End Sub

[William Rodrigues]

Valeu por ter colocado o código mais explícito Promotor Advanced

Valeu pelo tuto Bicicleta

Abraços,

William Rodrigues