VBA Formatação Condicional

[MColucci]

Olá, gostaria de saber como formatar em VBA uma planilha quando os valores nela forem diferentes, vou mostrar um exemplo prático:

Eu gostaria q nessa tabela alterasse por exemplo a borda inferior da linha em que o nome muda, desse jeito:

Sei que no Excel bastaria eu colocar =D2=D3 pra chegar em FALSO ou VERDADEIRO e assim filtrar e formatar como eu quisesse, mas em VBA não estou sabendo como fazer

Obs.: seria uma tabela com quantidade indefinida de linhas.

Se puderem me ajudar agradeço.

[Alyson Ronnan Martins]

Boa noite @MColucci

Eu recomendaria usar formatação condicional em vez de macro.
Qual motivo está vendo a necessidade de macro ?(pode ser que eu não esteja vendo o motivo)

[MColucci]

Boa noite, é que a pessoa que está precisando vai executar essa rotina e entre outras com uma frequência grande, todas de umas vez, fazer essa formatação manualmente tomaria um tempo do qual ela não tem muito. Vou colocar em uma macro Pessoal e criar um botão no menu pra executar

[Alyson Ronnan Martins]

Quantas colunas seriam para colocar com a borda inferior em uma espessura maior?

 

[MColucci]

Pode ser no caso do exemplo: 5 colunas.

Na prática vão ser mais, vão até a coluna "Q"

[Alyson Ronnan Martins]

Option Explicit


Public Sub FormatarBordarInferiorCasoDiferenteColunaD()
  Dim linha               As Long
  Dim UltimaLinha         As Long
  Dim valorCelulaAtual    As String
  Dim valurCelulaSuperior As String
  
  UltimaLinha = Cells(Rows.Count, "D").End(xlUp).Row
  
  'Formatar a ultima linha já que a inferior e diferênte
  FormatarBordarInferiorLinha UltimaLinha
  
  'Percorrer de baixo para cima fazendo a formatação da linha
  For linha = UltimaLinha To 2 Step -1
    valorCelulaAtual = Cells(linha, "D").Value
    valurCelulaSuperior = Cells(linha - 1, "D").Value
    
    If valorCelulaAtual <> valurCelulaSuperior Then
      FormatarBordarInferiorLinha linha - 1
    End If
    
  Next linha
End Sub


Public Sub FormatarBordarInferiorLinha(linha As Long)
  With Range(Cells(linha, "A"), Cells(linha, "E"))
    .Borders(xlEdgeBottom).LineStyle = xlContinuous
    .Borders(xlEdgeBottom).ColorIndex = xlAutomatic
    .Borders(xlEdgeBottom).TintAndShade = 0
    .Borders(xlEdgeBottom).Weight = xlMedium
  End With
End Sub

Verificar se ele está funcionando.

Editado Novembro 1, 2023 por Alyson Ronnan Martins
Correção da formulá

[MColucci]

Funcionou perfeito, muito obrigado!