NumPad não funciona - TextBox Moeda

[MColucci]

Tenho uma TextBox para digitar valores em R$

Achei esse código na internet que funcionou muito bem para a função que eu queria, mas não está aceitando digitar números do NumPad, só aceita os números que ficam em cima das letras no teclado. Se eu incluo exceção para os códigos de teclas do NumPad ele buga e não funciona direito.

Como posso consertar isso?

Private Sub txtValorCP_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)

    Dim zTemp As String

    txtValorCP.TextAlign = fmTextAlignRight
    If IsNumeric(Chr(KeyCode)) Or KeyCode = 8 Then
     If txtValorCP.Text <> "" Then
      zTemp = txtValorCP.Text & IIf(KeyCode <> 8, Chr(KeyCode), "")
      zTemp = Right(zTemp, Len(zTemp) - 2)
      zTemp = Replace(zTemp, ".", "")
      zTemp = Replace(zTemp, ",", "")
       If KeyCode = 8 Then
        If Len(zTemp) > 3 Then
         zTemp = Left(zTemp, Len(zTemp) - 1)
        Else
         zTemp = "0" & Left(zTemp, Len(zTemp) - 1)
        End If
       End If
      zTemp = Left(zTemp, Len(zTemp) - 2) & "." & Right(zTemp, 2)
     Else
      zTemp = "0.0" & IIf(KeyCode <> 8, Chr(KeyCode), "0")
     End If
     txtValorCP.Text = Format(Val(zTemp), "R$ ###,##0.00")
     KeyCode = 0
    Else
     If KeyCode <> 13 And KeyCode <> 9 And KeyCode <> 40 And KeyCode <> 38 Then KeyCode = 0
    End If
    
End Sub

Editado Novembro 9, 2023 por MColucci

[Alyson Ronnan Martins]

Boa tarde. @MColucci.

Private Sub txtValorCP_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)

    Dim zTemp As String

    txtValorCP.TextAlign = fmTextAlignRight
    If IsNumeric(Chr(KeyCode)) Or KeyCode = 8 Or (KeyCode >= 96 And KeyCode <= 105) Then
     If txtValorCP.Text <> "" Then
      zTemp = txtValorCP.Text & IIf(KeyCode <> 8, Chr(IIf(KeyCode >= 96 And KeyCode <= 105, KeyCode - 48, KeyCode)), "")
      zTemp = Right(zTemp, Len(zTemp) - 2)
      zTemp = Replace(zTemp, ".", "")
      zTemp = Replace(zTemp, ",", "")
       If KeyCode = 8 Then
        If Len(zTemp) > 3 Then
         zTemp = Left(zTemp, Len(zTemp) - 1)
        Else
         zTemp = "0" & Left(zTemp, Len(zTemp) - 1)
        End If
       End If
      zTemp = Left(zTemp, Len(zTemp) - 2) & "." & Right(zTemp, 2)
     Else
      zTemp = "0.0" & IIf(KeyCode <> 8, Chr(IIf(KeyCode >= 96 And KeyCode <= 105, KeyCode - 48, KeyCode)), "0")
     End If
     txtValorCP.Text = Format(Val(zTemp), "R$ ###,##0.00")
     KeyCode = 0
    Else
     If KeyCode <> 13 And KeyCode <> 9 And KeyCode <> 40 And KeyCode <> 38 Then KeyCode = 0
    End If
    
End Sub

Seu código foi adaptado coloca uma interpretação dos 'keycode' 96 ao 105 que são os números do teclado numério.

olha se funciona no seu código.

[MColucci]

Boa noite, tive uns probleminhas, mas consegui voltar aqui

Testei a adaptação, funcionou mesmo, muitíssimo obrigado, você é o cara