Api-função Exitwindowsex

[Paulo Nobre]

Tenho um alarme simples que usa a função API do windows

ExitWindowsEx

Para desligar o computador na hora estabelecida uso a constante EWX_SHUTDOWN = 1, da seguinte maneira

Dim Dummy as long

Dummy = ExitWindowsEx(1,0)

A função API é:

Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long

declarada no option explicit do form que faz sua chamada.

O problema é que funciona no Win98 e Me, mas não funciona no XP.

Alguém saberia dizer por que?

Obrigado pela atenção

Paulo Nobre

[Paulo Nobre]

Tentei usar ExitWindowsEx(EWX_Force,0), mas desta forma ele não desliga, apenas aparece a tela para reiniciar com logon.

Foi tentada também uma sugestão de um colega de outro forum, que seria combinar 1 + EWX_Force mas nada acontece.

Alguém poderia ajudar?

Existe alguma outra API para desligar?

Obrigado

Paulo Nobre

[Paulo Nobre]

Para todos que se dispuseram a ler ou tentar ajudar, consegui através de um colaborador(T@Z) de um outro forum este código:

esta função foi retirada do programa "API-Guide" disponivel para download em "http://www.allapi.net"(palavras dele)

'Insira isto em um módulo

Private Const EWX_LOGOFF = 0

Private Const EWX_SHUTDOWN = 1

Private Const EWX_REBOOT = 2

Private Const EWX_FORCE = 4

Private Const TOKEN_ADJUST_PRIVILEGES = &H20

Private Const TOKEN_QUERY = &H8

Private Const SE_PRIVILEGE_ENABLED = &H2

Private Const ANYSIZE_ARRAY = 1

Private Const VER_PLATFORM_WIN32_NT = 2

Type OSVERSIONINFO

dwOSVersionInfoSize As Long

dwMajorVersion As Long

dwMinorVersion As Long

dwBuildNumber As Long

dwPlatformId As Long

szCSDVersion As String * 128

End Type

Type LUID

LowPart As Long

HighPart As Long

End Type

Type LUID_AND_ATTRIBUTES

pLuid As LUID

Attributes As Long

End Type

Type TOKEN_PRIVILEGES

PrivilegeCount As Long

Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES

End Type

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long

Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long

Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long

Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long

Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long

Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long

'Detect if the program is running under Windows NT

Public Function IsWinNT() As Boolean

Dim myOS As OSVERSIONINFO

myOS.dwOSVersionInfoSize = Len(myOS)

GetVersionEx myOS

IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)

End Function

'set the shut down privilege for the current application

Private Sub EnableShutDown()

Dim hProc As Long

Dim hToken As Long

Dim mLUID As LUID

Dim mPriv As TOKEN_PRIVILEGES

Dim mNewPriv As TOKEN_PRIVILEGES

hProc = GetCurrentProcess()

OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken

LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID

mPriv.PrivilegeCount = 1

mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED

mPriv.Privileges(0).pLuid = mLUID

' enable shutdown privilege for the current application

AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)

End Sub

' Shut Down NT

Public Sub ShutDownNT(Force As Boolean)

Dim ret As Long

Dim Flags As Long

Flags = EWX_SHUTDOWN

If Force Then Flags = Flags + EWX_FORCE

If IsWinNT Then EnableShutDown

ExitWindowsEx Flags, 0

End Sub

'Restart NT

Public Sub RebootNT(Force As Boolean)

Dim ret As Long

Dim Flags As Long

Flags = EWX_REBOOT

If Force Then Flags = Flags + EWX_FORCE

If IsWinNT Then EnableShutDown

ExitWindowsEx Flags, 0

End Sub

'Log off the current user

Public Sub LogOffNT(Force As Boolean)

Dim ret As Long

Dim Flags As Long

Flags = EWX_LOGOFF

If Force Then Flags = Flags + EWX_FORCE

ExitWindowsEx Flags, 0

End Sub

crie um formulário com 3 botões

Private Sub Command1_Click()

LogOffNT True

End Sub

Private Sub Command2_Click()

RebootNT True

End Sub

Private Sub Command3_Click()

ShutDownNT True

End Sub

Private Sub Form_Load()

'KPD-Team 2000

'URL: http://www.allapi.net/

'E-Mail: KPDTeam@Allapi.net

Command1.Caption = "Log Off NT"

Command2.Caption = "Reboot NT"

Command3.Caption = "Shutdown NT"

End Sub

tive que adaptar o código no shutdown, colocando flag = EWX_POWEROFF e incluindo const = EWX_POWEROFF = 8, pois se não fizesse isto não desligava direto e sim aparecia aquela tela final dizendo que agora o computador já pode ser desligado.

Por outro lado veja como programação tem detalhes e é dificil(pra mim que sou leigo-sou professor de matemática e uso prá brincar)

nos computadores "caseiros"(sem senha) tudo bem,mas, levei para testar na escola onde trabalho que tem Windows 98, pois estava cabreiro com o fato do código fazer o teste em cima do NT.Como os computadores tem senha (acho que este é o problema), na hora programada do alarme para desligar, ao invés de desligar,aparecia a caixa da senha para entrar no sitema, mas não desligava e ainda para piorar o programa desaparecia da tela e ficava em segundo plano.

ou seja o problema continua

obrigado a quem se dispuser a ajudar

Paulo Nobre

[William Rodrigues]

Para todos que se dispuseram a ler ou tentar ajudar, consegui através de um colaborador(T@Z) de um outro forum este código:

Valeu Paulo Nobre por ter colocado o código aí para nós...

Meio complicado mas vou ver no que posso te ajudar

Abraços,

William Rodrigues

[Paulo Nobre]

Obrigado a você, William, pela gentileza de sua atenção.

Paulo Nobre

[William Rodrigues]

Obrigado a você, William, pela gentileza de sua atenção.

Imagina brother...

Vou estar migrando para o XP hoje e verei no que posso te ajudar

Abraços,

William Rodrigues

[Guest - Ricardo -]

Usem a função do shell: C:\WINDOWS\RUNDLL.EXE USER.EXE,EXITWINDOWS. ricardomada@pop.com.br