Formulário De Envio Simples

[Guest - Juliana -]

Olá novamente amigos! Tenho uma dúvida, preciso criar um formulário de contato para meu site, peguei alguns modelos prontos na net, porém não funcionaram.

usei um modelo q tem esse código no inicio (linha 2)

Set Mailer = Server.CreateObject("SMTPsvg.Mailer")

porém, quando vou testar, dá o seguinte erro:

Objeto Server error 'ASP 0177 : 800401f3'

Falha em Server.CreateObject

/english/enviaemail.asp, line 2

800401f3

existe algum modelo simples que vocês possam me mostrar?

obrigada!!

[Rob_g2*6(sic)6]

porque você num usa o CDONTS ............

Hehe ........

ABraços......

<%

Set Mailer = CreateObject("CDONTS.NewMail")

Mailer.From = "eu@dominio.com.br" ' e-mail de quem esta enviando a mensagem

Mailer.To = "conta@destinatario.com.br" ' e-mail de quem vai receber a mensagem

Mailer.CC = "conta@destinatario.com.br" ' Com Cópia

Mailer.BodyFormat = 1 ' parametro de formatação

Mailer.MailFormat = cdoMailFormatText ' parametro de formatação

Mailer.AttachFile "e:\home\login\dados\arquivo.txt" 'caso queira anexar algum arquivo ao seu e-mail

Mailer.Subject = "Assunto do E-mail"

Mailer.Body = "Corpo da Mensagem"

Mailer.Send

Set Mailer = Nothing

%>

Atenção: O CDONTS está disponível apenas em servidores com o IIS 5.0

Para saber em qual versão do IIS seu site está instalado, basta colocar o script abaixo em uma página ASP e executar a mesma.

<%

Response.Write Request.ServerVariables("SERVER_SOFTWARE")

%>

[Guest Guest]

usei um modelo com esse cdonts e tb não funcionou...

[TBANet]

Olá Juliana eu estava tendo o mesmo problema que você fui descobrir que o servidor que eu estava usando não suportava o aspmail que usa o SMTPsvg..A solução disso foi trocar para o aspemail que usa o componente Persist.

No caso não muda muito o código de uma olhada neste exemplo:

Set Mailer = Server.CreateObject("Persits.MailSender")

Mailer.IsHTML = True

Mailer.FromName = contato

Mailer.From = email

Mailer.Host = "smtp.server.com.br"

Mailer.AddAddress "seu@email.com.br"

Mailer.Subject = "Teste"

Mailer.Body = mensagem

if Mailer.Send = 0 then

Server.Transfer("erro.asp")

else

Server.Transfer("confirmacao.html")

end if

Bom espero que isto te ajude.

[jntk]

Cara esses forms prontos da net são uma droga a maioria não funcionam.

Eu tenho um form.mail pronto com duas páginas, uma em html (o form.) e a outra em asp (a página que le os dados do form e envia para o seu e-mail)

Se quiser posso te enviar via e-mail

Mande um e-mail pra mim, que te respondo com o anexo, ok?

um abraço

Jônatas Soares

webmaster@ieqquitauna.com.br

[Rob_g2*6(sic)6]

você ESTA USANDO NO SEU MICRO .........?

Se tiver, no seu micro você pode usar o componente que quiser que nunca vai enviar nada se não configurar o Servidor de SMTP....

[Tiago Correa]

tente este ... mas será necessário que você manipule as informações de acordo com suas necessidades .... ok?

----------------- formulario simples--------------------------------------------------------

<form name="form1" method="post" action="nome da pagina.asp">

<table width="500" border="1">

<tr>

<td>nome:</td>

<td><input name="nome" type="text" id="nome"></td>

</tr>

<tr>

<td>tel:</td>

<td><input name="tel" type="text" id="tel"></td>

</tr>

<tr>

<td>email:</td>

<td><input name="email" type="text" id="email"></td>

</tr>

<tr>

<td>coment&aacute;rios</td>

<td><textarea name="comentarios" id="comentarios"></textarea></td>

</tr>

<tr>

<td><input type="submit" name="Submit" value="Submit"></td>

<td>&nbsp;</td>

</tr>

</table>

<p>&nbsp; </p>

</form>

-------------------------------------- página de envio.asp ---------------------------------

<%

corpo = request.form("nome")

corpo = corpo & request.form("tel")

corpo = corpo & request.form("email")

corpo = corpo & request.form("descricao")

set objMail=server.createobject("CDONTS.NewMail")

objMail.From="Web"

objMail.To="endereço de email do seu dominio"

objMail.Cc="endereco para cópia"

objMail.Subject="Assunto"

objMail.Body=corpo 'corpo da MSN ... que tb pode ser uma variavel

objMail.Importance=1

objMail.Send

%>

[cyberalexxx]

Este é o formulario com o CDONTS que esta funcionando em meu site:

contato.asp

<%

'email que recebera as mensagens

sYouEmail="xxxxxxx@xxxxxxxxxxx.com.br"

'campo assunto do email

EmailSubject="mensagem de usuario do SITE"

'cores do formulario

FontColor="#3333FF"

HeadColor="#ffc500"

FormFontColor="#FFFFFF"

FormBackColor="#3333FF"

ErrorColor="red"

Function ValidateField(sFieldvalue, sFieldtype)

ValidField = true

Select Case LCase(sFieldtype)

Case "name"

If Len(sFieldvalue) = 0 Then ValidField = False

Case "email"

If Len(sFieldvalue) < 5 Then

ValidField = False

Else

If InStr(1, sFieldvalue, "@", 1) < 2 Then

ValidField = False

Else

If InStr(1, sFieldvalue, ".", 1) < 4 Then

ValidField = False

End If

End If

End If

Case "message"

If Len(sFieldvalue) = 0 Then ValidField = False

Case "else"

ValidField = False

End Select

ValidateField = ValidField

End Function

Sub ShowForm

%>

<table border="1" cellpadding="0" cellspacing="0" style="border-collapse: collapse" bordercolor="#FFFFFF" width="634">

<tr>

<td width="100%">&nbsp;<center><form action="<%= Request.ServerVariables("Script_Name") %>" method="post">

<p>&nbsp;</p>

<table border="0" cellspacing="0" width="240" cellpadding=0><tr bgcolor="<%=HeadColor%>">

<td ALIGN="left"><font color="<%=FontColor%>" face="verdana,arial,helvetica" size="-1"><B>

Seu Nome:</B></font>&nbsp;</td></tr>

<tr><td><input name="name" type="text" value="<%= Request.Form("name") %>" SIZE="45" style="FONT-SIZE: 11px; COLOR: <%=FormFontcolor%>; FONT-FAMILY: verdana, helvetica, arial; BACKGROUND-COLOR: <%=FormBackColor%>"></INPUT></td>

</tr><tr><td><%

If dictFields(LCase("name")) Then

Response.Write "<font color=""" & ErrorColor & """ face=""verdana,arial,helvetica"" size=-2>Voce precisa informar um nome</font>"

Else

Response.Write "&nbsp;"

End If

%>

</td></tr>

<tr bgcolor="<%=HeadColor%>">

<td ALIGN="left"><font color="#3333FF" face="verdana,arial,helvetica" size="-1"><B>email:</B></font>&nbsp;</td></tr>

<tr><td><input name="email" type="text" value="<%= Request.Form("email") %>" SIZE="45" style="FONT-SIZE: 11px; COLOR: <%=FormFontcolor%>; FONT-FAMILY: verdana, helvetica, arial; BACKGROUND-COLOR: <%=FormBackColor%>"></INPUT></td>

</tr><tr><td><%

If dictFields(LCase("email")) Then

Response.Write "<font color=""" & ErrorColor & """ face=""verdana,arial,helvetica"" size=-2>voce precisa informar um endereço de email valido</font>"

Else

Response.Write "&nbsp;"

End If

%>

</td></tr>

<tr bgcolor="<%=HeadColor%>">

<td ALIGN="left"><font color="#3333FF" face="verdana,arial,helvetica" size="-1"><B>

Mensagem:</B></font>&nbsp;</td></tr>

<tr><td><TEXTAREA NAME="message" WRAP=VIRTUAL COLS="45" ROWS=7 style="FONT-SIZE: 11px; COLOR: <%=FormFontcolor%>; FONT-FAMILY: verdana, helvetica, arial; BACKGROUND-COLOR: <%=FormBackColor%>"><%= Request.Form("message") %></TEXTAREA></td>

</tr><tr><td><%

If dictFields(LCase("message")) Then

Response.Write "<font color=""" & ErrorColor & """ face=""verdana,arial,helvetica"" size=-2> Você precisa digitar uma mensagem</font>"

Else

Response.Write "&nbsp;"

End If

%>

</td></tr>

<tr><td colspan=2><font color="#000000" face="verdana,arial,helvetica" size="-1"><input type="checkbox" name="agree" value="true" <%

if Len(Request.Form("agree")) > 0 then

Response.Write "checked"

End If

%>> Clique aqui caso deseje fazer parte de nossa lista de contatos</td></tr>

</table><p><input type="submit" value="Envia Mensagem"></input><br></form>

<P>

<%

End Sub

Sub Send

sPunter = Request.Form("Name")

sPunterEmail = Request.Form("Email")

Message = Request.Form("message")

If Request.Form("agree") = "true" then

Mailout = "Ele deseja ser incluido em nossa lista de contatos"

Else

Mailout ="Ele NÃO deseja ser incluido em nossa lista de contatos"

End If

sMessage = "Essa é uma mensagem de " & sPunter & vbcrlf _

& vbcrlf _

& vbcrlf _

& Message & vbcrlf _

& vbcrlf _

& "Seu email é: " & sPunterEmail & vbcrlf _

& vbcrlf _

& Mailout & vbcrlf _

& vbcrlf

Set objNewMail = CreateObject("CDONTS.NewMail")

objNewMail.Send sPunterEmail, sYouEmail, EmailSubject, sMessage

Set objNewMail = Nothing

End Sub

Set dictFields = Server.CreateObject("Scripting.Dictionary")

For Each Field in Request.Form

If ValidateField(Request.Form(Field), Field) = False Then

dictFields.Add LCase(Field), true

End If

Next

If Request.Form.Count <> 0 And dictFields.Count = 0 Then

%><P>

&nbsp;<P>

&nbsp;<b>Sua Mensagem foi enviada!<BR></b><P><b><i>Obrigado por entrar em contato.</i></b><BR>

<%

Call Send

Else

ShowForm

End If

%>

[bareta]

você esta usando um server gratis?? se for não vai funciona.....tem que ver isso....se é pago veja se ele tem o componente.......

[TBANet]

você está utilizando um servidor remoto?

caso isso este servidor suporta asp e seus componentes?

c não tiver esses componentes(CDonts,ASPMail,ASPEmail,etc) registrados no servidor você pode tentar varios códigos que nenhum irá funcionar.

[Guest - Juliana -]

estou testando local (pws) é versao 4

ainda não testei remoto, mas tenho uma conta no domaindlx.com que dá suporte ao asp

abraços

[bareta]

que componentes você tem instalados no seu pc? (cdonts,jmail,aspmail....você tem que ter eles na sua maquina.........

[Guest Carlos Seiji]

no seu caso você vai ter de instalar algum componente de e-mail.

cdonts esquece porque você não vai conseguir configurar o smtp.

te aconselho a instalar um win2k ou win xp para utilizar o IIS

pws é muito fraco.

[]'s

[Victor]

Você tem algum componente instalado no seu PC ai?? Ou no servidor?

[Guest - Juliana -]

Então.... eu sou programadora delphi, eu nunca tinha trabalhado com asp... então não tenho mta noção

quanto ao windows, aqui é o 98 porque a maquina não aguenta o xp... estou trabalhando com o sistema administrativo da empresa, estou (re)fazendo o site porque tenho um pouco de noção sobre isso...

se não der pra montar o form em asp, tem outro jeito, ou só no cgi mesmo? abraços

[dark0]

Juli..

me explica aí o que você quer fazer

Tipo, se eu entendi, você quer montar um formulario de envio de e-mail em asp, né?

Bom, você esta usando pws, certo?

então, antes de mais nada.. você vai rodar esse codigo apenas localmente, ou pretende lançar na web depois?

porque, em asp, o esquema funciona assim:

Primeiro, você vê onde vai hospedar o site.

Depois, você vê qual componente aquele servidor suporta.

Aí, sabendo o componente, você começa a desenvolver o código para esse componente.

Visto que são varios componentes que podem ser usados. Alguns free e outros não.

então, se você pretende rodar localmente, no pws, você vai precisar instalar algum componente.

Depois, bolar o codigo, e fazer funcionar.

Abraços

[Victor]

Se você não tiver componente... o unico que resta e você usar o form-mail do scriptbrasil... Ele é bom!!!! Só que em HTML

[Guest - Juliana -]

falei do form em asp pois uso asp em algumas partes do site... mas não precisa necessariamente ser em asp

quanto aos componentes,,, estou testando localmente porque estamos mudando de servidor, e ainda não sei quais os componentes disponiveis no novo servidor.

mas obrigada assim mesmo pela ajuda de todos

um abraço

[Guest - Juliana -]

em q sessao do site esta esse form-mail? obrigada!

[dark0]

falei do form em asp pois uso asp em algumas partes do site... mas não precisa necessariamente ser em asp

quanto aos componentes,,, estou testando localmente porque estamos mudando de servidor, e ainda não sei quais os componentes disponiveis no novo servidor.

mas obrigada assim mesmo pela ajuda de todos

um abraço

hehehe

então, o que você pretende fazer?

quer tentar instalar o cdonts aí, e ir bolando alguma coisa, pra testes?

veja uma explicação de como instalar o CDONTS aqui:

http://scriptbrasil.com.br/forum/index.php...ndpost&p=108877

eu testei isso aí no XP Pro, com IIS, porem, você pode testar isso no pws do 98, e se não der, já posta aí, que a gente já fica sabendo tb, hehe

Abraços

[Guest - Juliana -]

é, acho q não deu,,,,

quando digito no prompt RegSvr32 cdonts.dll

dá comando ou nome de arquivo invalido

acho q vou ter q esperar mesmo hehehehe

abraços

[dark0]

ahh

hehe

tipo.. então, esse comando deve ser diferente no windows 98.

vou dar uma pesquisada aqui, qualquer novidade, posto pra vc!

abraços