Ir para conteúdo
Fórum Script Brasil
  • 0

Topico Exclusivo - Componentes De E-mail - 1 !

dark0

Perguntado por dark0,

 Share

Pergunta

dark0

dark0

Postado
Postado

Olá Pessoal, Tudo bem?

Estou iniciando uma série de Tópicos para Falar sobre Componentes de E-mail!

Vou criar para cada componente um Tópico!

Nesse, vamos discutir CDONTS!

Aqui, postem Duvidas, Soluções, Dicas, Códigos !!!

CDONTS

...É um componente também utilizado para envio de e-mails. Ele é parte integrante do IIS dos servidores Windows 2000 e utiliza o serviço de envio de e-mails (SMTP) do servidor onde ele se encontra.

Onde baixar a DLL, e como Instalar

http://scriptbrasil.com.br/forum/index.php...ndpost&p=108877

Documentação do 'Fabricante'

http://msdn.microsoft.com/library/default....ts_library_.asp

Um exemplo de código:

<%
if request("botao") = "enviar" then
Dim objNewMail
Set objNewMail = Server.CreateObject("CDONTS.NewMail")
objNewMail.From = "email@seudominio.com.br"
objNewMail.To = request("to")
objNewMail.Subject = request("subject")
objNewMail.Body = request("body")
e=objNewMail.Send

if e then
Response.Write "Mensagem não enviada"
else
Response.Write "Mensagem enviada com sucesso"
end if
response.end
end if
%>

<html>
<body>
<form method="POST" action="cdonts.asp">
<table border="0" width="43%">
<tr>
<td width="13%"><strong>Para:</strong></td>
<td width="87%"><input type="text" name="to" size="32"></td>
</tr>
<tr>
<td width="13%"><strong>Assunto:</strong></td>
<td width="87%"><input type="text" name="subject" size="32"></td>
</tr>
<tr>
<td width="13%"><strong>Mensagem:</strong></td>
<td width="87%"><textarea rows="7" name="body" cols="43"></textarea></td>
</tr>
<tr>
<td width="13%"></td>
<td width="87%"><input type="submit" value="enviar" name="botao"></td>
</tr>
</table>
</form>
</body>
</html>

...No campo: objNewMail.From = "email@seudominio.com.br" substitua pelo e-mail de seu domínio.

O Codigo acima foi tirado de:

http://www.digiweb.com.br/suporte/windows/cdonts/index.asp

Então galera, se tiverem alguma duvida em relação à esse componente, postem aqui!

Vamos fazer uma referência sobre CDONTS!

Logo, Logo, Colocarei Outro Componente, e assim, vou seguindo, até colocar.. ou todos, ou pelo menos os principais!

Abraços, e até mais!

Dark0!

Link para o comentário
Compartilhar em outros sites

44 respostass a esta questão

Posts Recomendados

  • 0
cyberalexxx

cyberalexxx

Postado
Postado
Pessoal tenho uma dúvida... instalei o IIS tah funcionando perfeitamente... só tem 1 porém... eu estou tentando enviar um email pelo componente cdonts e não funciona... eu não recebi o email, mas acho que é algum problema com o SMTP, mas alguém aí sabe como eu faço para configurar o SMTP para enviar hotmail ou yahoo ou gmail ou qualquer outro mail??? Um tuto??!?

Valeu

No caso do hotmail, você verificou c o email não entrou na pasta de lixo eletronico???

Link para o comentário
Compartilhar em outros sites
  • 0
dark0

dark0

Postado
  • Autor
Postado

guto, você testou o codigo que coloquei no primeiro post?

se o smtp está com algum problema, experimente desinatalar e instalar de novo.

isso geralmente resolve problemas com cdonts

Link para o comentário
Compartilhar em outros sites
  • 0
[ GuTo ]

[ GuTo ]

Postado
Postado

Dae darko!

Talvez seja isso mesmo de reinstalar o CDONTS.

porque meu código é semelhante ao seu.

A linha desta parte do código é assim:

If .Send Then EnviaEmail = True

EnviaEmail é o nome da função que uso para enviar emails, apenas selecionando qual componente quero usar! wink.gif

Link para o comentário
Compartilhar em outros sites
  • 0
dark0

dark0

Postado
  • Autor
Postado

Seria:

if EnviaEmail.Send = true then

enviou

else

não enviou

end if

??

Link para o comentário
Compartilhar em outros sites
  • 0
[ GuTo ]

[ GuTo ]

Postado
Postado

Isso mesmo!

É que esta assim:

With objMail 'objMail é o nome do objeto que está setado, no qual esta usando o CDONTS
  '// ROTINA TODA DO EMAIL ( DESTINATARIO, REMETENTE, ASSUNTO...)
  If .Send Then EnviaEmail = True
End With
É a mesma coisa que tu escreveu aí em cima, retorna exatamente isso, só que é uma maneira reduzida/optimizada. Dae para eu chamar a função na página, eu faço um include da função, e depois chamo-a assim: 
If EnviaEmail(NomeRem, EmailRem, NomeDest, EmailDest, Assunto, CorpoDaMsg,True) Then 'Este último true é para o caso do HTML sim OU texto comum FALSE
  'enviado
Else
  'não enviado
End If

Sacou?

É mais ou menos isso!

No entanto, no CDONTS e no CDOSYS não retorna true!

O CDONTS eu testei no server do jissa (retrieve.com.br)

Link para o comentário
Compartilhar em outros sites
  • 0
Guest G@t@

Guest G@t@

Postado
Postado

beleza galega, mas eu quero saber se tenho que configurar alguma coisa ou ele manda direto?!? Ou seja sem configurar... digo isso porque no IIS você tem q configurar o Alias e tals...

Valeu!

Link para o comentário
Compartilhar em outros sites
  • 0
dark0

dark0

Postado
  • Autor
Postado

você precisa ter o IIs e o Servidor de SMTP do IIS instalado, e a DLL do cdonts registrada

depois é só rodar o codigo que ele funciona na boa

Link para o comentário
Compartilhar em outros sites
  • 0
Graymalkin

Graymalkin

Postado
Postado

Humm... posso colaborar também? Bom, segue o link para o componente Py.Sendmail: http://www.graymalkin.globalhosts.com.br/pysendmail.asp. É um componente COM, portanto vai (deve) funcionar com qualquer linguagem COM-Compliant, o que inclui VBScript. O pacote já inclui exemplos em diversas linguagens (o de VB pode muito bem ser "aproveitado" para o caso do VBScript).

Abraços,

Graymalkin

Link para o comentário
Compartilhar em outros sites
  • 0
dark0

dark0

Postado
  • Autor
Postado

er..

legal cara..

mas explica mais como isso aí funciona..

Ele tem algo relacionado ào CDONTS?

Valeu a colaboração.

E quanto à:

Qual teste devo fazer para saber se o servidor onde esta hospeda minha página tem suporte para CDONTS

você deve rodar algum codigo que lista os componentes instalados.

Visite o tópico de funcoes, que você vai ver alguns exemplos lá

Abraço

Link para o comentário
Compartilhar em outros sites
  • 0
Graymalkin

Graymalkin

Postado
Postado

er..

legal cara..

mas explica mais como isso aí funciona..

Ele tem algo relacionado ào CDONTS?

Não, ele é independente. Tecnicamente falando, você pode utilizar ele *no lugar* do CDONTS. Como o título do tópico é "Componentes De E-mail - 1!", ou seja, "Componentes" (no plural), decidi apresentar ele como mais um dos "componentes" existentes. Algumas características interessantes dele são:

* você pode optar entre e-mail puro ou HTML;

* autenticação;

* inclusão de anexos às mensagens;

* você pode embutir uma figura diretamente no código HTML da mensagem (não é um link: é a imagem mesmo - codificada em Base64).

Ele foi totalmente desenvolvido em Python (e acompanha o código-fonte para quem quiser extendê-lo), e compilado como um componente COM, ou seja, pode ser utilizado em qualquer linguagem dê suporte ao COM (como VBScript, Visual Basic, Python, Delphi, Ruby, Java e xHarbour, por exemplo).

Valeu a colaboração.

Obrigado. biggrin.gif

Link para o comentário
Compartilhar em outros sites
  • 0
Super_Zica_Man

Super_Zica_Man

Postado
Postado

cara querendo acrescentar os tipos de form mail em CDONTS que achei numa pesquisa....

(Pls adiciona isso no seu tópico pode ser muito util.....)

CDONTS

CDONTS são scripts com as instruções para enviar e-mails com o CDONTS no ASP.

E-mail anexo:

<%

set objMail = server.createobject("CDONTS.NewMail")

objMail.From = "remetente@servidor.com.br"

objMail.To = "destino@servidor.com.br"

objMail.Subject = "E-mail com anexo"

objMail.Body = "Segue o arquivo teste.gif"

objMail.MailFormat = 0

objMail.Attachfile "c:\caminho\seusite\teste.gif", "teste.gif"

objMail.Send

Response.Write "Mensagem Enviada"

set objMail = Nothing

%>

E-mail Básico:

<%

set objMail = server.createobject("CDONTS.NewMail")

objMail.From = "remetente@servidor.com.br"

objMail.To = "destino1@servidor.com.br"

objMail.Cc = "destino2@servidor.com.br"

objMail.Bcc = "destino3@servidor.com.br"

objMail.Subject = "Assunto"

objMail.Body = "Corpo da Mensagem"

objMail.Importance = 1

objMail.Send

Response.Write "Mensagem Enviada"

set objMail = Nothing

%>

E-mail Embutido:

<%

set objMail = server.createobject("CDONTS.NewMail")

objMail.From = "remetente@servidor.com.br"

objMail.To = "destino@servidor.com.br"

objMail.Subject = "E-mail com anexo"

objMail.Body = "<html><body><img src=""teste.gif""></body></html>"

objMail.BodyFormat = 0

objMail.MailFormat = 0

objMail.AttachURL "c:\caminho\seusite\teste.gif", "teste.gif"

objMail.Send

Response.Write "Mensagem Enviada"

set objMail = Nothing

%>

E-mail HTML:

<%

set objMail = server.createobject("CDONTS.NewMail")

objMail.From = "remetente@servidor.com.br"

objMail.To = "destino@servidor.com.br"

objMail.Subject = "E-mail HTML"

objMail.Body = "<html><body>Revista <span style=""color:#ff0000;text-weight:bold"">www.com.br</span>" & _

"<br><a href=""http://www.seusite.com.br/"">Seu site</a></body></html>"

objMail.BodyFormat = 0

objMail.MailFormat = 0

objMail.Send

Response.Write "Mensagem Enviada"

set objMail = Nothing

%>

Fonte: Revista WWW.com.br

Encontrado no site:http://www.htmlstaff.org/asp/asp46.php

Link para o comentário
Compartilhar em outros sites
  • 0
Elton M. Távora

Elton M. Távora

Postado
Postado

Galera... estou com um código do cdont e o envio do e-mail funciona quando rodo a página pela minha máquina.

Quando eu fui rodar a página pelo servidor do site que dou suporte é apresentado um erro na lina 26 do meu código.

Queria saber se alguém consegue matar esse erro.

Segue o código:

<%

Option Explicit

Dim var_nome, var_empresa, var_mail, var_to, EnviarMail, MsgBody

var_nome = Request.QueryString("txtnome")
var_empresa = Request.QueryString("txtempresa")
var_mail = Request.QueryString("txtemail")

Set EnviarMail = Server.CreateObject("CDONTS.NewMail")
EnviarMail.To = "elton@UMSERVIDOR QUALQUER.com.br"
EnviarMail.From = "marcilio@UMSERVIDORQUALQUER.com.br"
EnviarMail.Subject = "Email enviado pelo site."
MsgBody = "<html>" _
& "<head>" _
& "</head>" _
& "<body bgcolor=""#FFFFFF"">" _
& "<p><font face=""Verdana, Arial, Helvetica, sans-serif"" size=""2"">Nome: <b>" & var_nome & "</b><br>Empresa: <b>" & var_empresa & "</b><br> Email: <b>" & var_mail & "</b><br> Comentário: E-mail enviado automaticamente.<b></b></font></p>" _
& "</body>" _
& "</html>"
EnviarMail.Body = MsgBody
EnviarMail.Importance = 1
EnviarMail.BodyFormat = 0
EnviarMail.MailFormat = 0
EnviarMail.Send

Set EnviarMail = Nothing

Response.redirect "Obrigado.html"

%>
Essa é a linha 26: 
EnviarMail.Send

Eu liguei para o pessoal que dá suporte ao servidor e me disseram que eu tenho que configurar o SMTP no meu código.

Se for realmente isso, alguém sabe como fazer?

Obrigado.

Link para o comentário
Compartilhar em outros sites
  • 0
Rafael Spilki

Rafael Spilki

Postado
Postado

Exatamente... você precisa autenticar o seu smtp...

taí uma forma de autenticação:

sch = "http://schemas.microsoft.com/cdo/configuration/"
Set cdoConfig = Server.CreateObject("CDO.Configuration")

cdoConfig.Fields.Item(sch & "sendusing") = 2
cdoConfig.Fields.Item(sch & "smtpauthenticate") = 1
cdoConfig.Fields.Item(sch & "smtpserver") = "AQUI VAI O HOST DE ENVIO"
cdoConfig.Fields.Item(sch & "smtpserverport") = 25
cdoConfig.Fields.Item(sch & "sendusing") = 2
cdoConfig.Fields.Item(sch & "smtpconnectiontimeout") = 30
cdoConfig.Fields.Item(sch & "sendusername") = "SEUEMAIL@SEUDOMINIO.COM.BR"
cdoConfig.Fields.Item(sch & "sendpassword") = "SUASENHA"
cdoConfig.fields.update
Set cdoMessage = Server.CreateObject("CDO.Message")
Set cdoMessage.Configuration = cdoConfig

cdoMessage.From = ""
cdoMessage.To = ""
cdoMessage.Subject = ""

htmlText = "MENSAGEM DO EMAIL"

cdoMessage.HTMLBody = htmlText
On Error Resume Next
cdoMessage.Send
Set cdoMessage = Nothing
Set cdoConfig = Nothing

[]'s Rafael Spilki

Link para o comentário
Compartilhar em outros sites
  • 0
bareta

bareta

Postado
Postado

no meu ultimo sistema que criei tive problemas com envio autenticado...

porque o cdosys dava erro no asp quando o endereço não exxistia, tive de usar 127.0.0.1 como smtp. e o tratamente de erros na pagina zuava o sistema de envio...

www.portalmaracaju.com.br/cg_newsletter

pra quiser ver...

Link para o comentário
Compartilhar em outros sites

Participe da discussão

Você pode postar agora e se registrar depois. Se você já tem uma conta, acesse agora para postar com sua conta.

Visitante
Responder esta pergunta...

×   Você colou conteúdo com formatação.   Remover formatação

  Apenas 75 emoticons são permitidos.

×   Seu link foi incorporado automaticamente.   Exibir como um link em vez disso

×   Seu conteúdo anterior foi restaurado.   Limpar Editor

×   Você não pode colar imagens diretamente. Carregar ou inserir imagens do URL.

×
 Share
Ir para lista de Perguntas


  • Estatísticas dos Fóruns

    • Tópicos
      152,3k
    • Posts
      652,5k
×
×
  • Criar Novo...