Como Fazer Para Automatizar A Digitação ?

[BrunoCastro]

Amigos,

Como faço para que ao digitar, numa combo, à medida que o usuário insere os caracteres, o controle mostre o registro mais adequado ao que o usuário está digitando ?

Valeu !!!

[PiGmEu]

você insere este codio em um Module

    #If Win32 Then
        Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
            (ByVal hwnd As Long, ByVal wMsg As Long, _
             ByVal wParam As Long, lParam As Any) As Long
    #Else
        Declare Function SendMessage Lib "User" _
            (ByVal hwnd As Integer, ByVal wMsg As Integer, _
             ByVal wParam As Integer, lParam As Any) As Long
    #End If

depois no evento KeyPress do seu Combobox você insere este aki

    Dim CB As Long
    Dim FindString As String
    Const CB_ERR = (-1)
    Const CB_FINDSTRING = &H14C
    
    If KeyAscii < 32 Or KeyAscii > 127 Then Exit Sub
    
    If cmb_123.SelLength = 0 Then
        FindString = cmb_123.Text & Chr$(KeyAscii)
    Else
        FindString = Left$(cmb_123.Text, cmb_123.SelStart) & Chr$(KeyAscii)
    End If
    
    CB = SendMessage(cmb_123.hwnd, CB_FINDSTRING, -1, ByVal FindString)
    
    If CB <> CB_ERR Then
        cmb_123.ListIndex = CB
        cmb_123.SelStart = Len(FindString)
        cmb_123.SelLength = Len(cmb_123.Text) - cmb_123.SelStart
    End If
    KeyAscii = 0

Obs. é so trocar o cmb_123 pelo nome do seu Combobox!

[]´s