Ir para conteúdo
Fórum Script Brasil
  • 0

Formulario Enviar Pelo E-mail

tsarri

Perguntado por tsarri,

 Share

Pergunta

tsarri

tsarri

Postado
Postado

Galera tenho um formulario um fale conoco e é enviado pelo e-mail não pelo banco de dados é da dando erro, alguém sabe o q devo fazer

<%

SUB errorForm ( theError )

%>

<html>

  <head>

  <title>:: Bem-vindo ao Web Site da STAR BRINDES ::</title>

  <base target="novo">

  <STYLE>

    BODY {SCROLLBAR-FACE-COLOR: #FFFFFF;

    SCROLLBAR-HIGHLIGHT-COLOR: #C0C0C0;

    SCROLLBAR-SHADOW-COLOR: #C0C0C0;

    SCROLLBAR-1DLIGHT-COLOR: #C0C0C0;

    SCROLLBAR-ARROW-COLOR:  #C0C0C0;

    SCROLLBAR-TRACK-COLOR: #cccccc;

    SCROLLBAR-DARKSHADOW-COLOR: #C0C0C0; }

  </STYLE>

  </head>

  <body topmargin="0" leftmargin="0" background="img_home/img-centro_iframe.jpg" bgproperties="fixed">

  <div align="center">

  <form method="post" action="contato_iframe.asp">

  <%=theError %>

  &nbsp;<p><b><font face="Verdana" size="2">

  <a href="javascript:history.go(-1)">Retornar</a></font></b> </p>

  <center>&nbsp;</center>

  <table border="0" cellpadding="4" width="580">

  <tr>

  <% FOR EACH item IN Request.Form %>

  <INPUT name="<%=item%>" type="hidden" value="<%=Server.HTMLEncode( Request.Form( item ) )%>">

      <% NEXT %>

 

<%

Response.End

END SUB

%>

<%

'Recupere Campos do Formulário

  Nome        = TRIM ( Request.Form( "Nome" ) )

  email  = TRIM ( Request.Form( "email" ) )

  ddd  = TRIM ( Request.Form( "ddd" ) )

  fone  = TRIM ( Request.Form( "fone" ) )

  comentarios = TRIM ( Request.Form( "comentarios" ) )

'Verifique  para se há campos requeridos

  IF Nome = "" THEN

          errorForm "Você não entrou com o Nome!"

        END IF

  IF email = "" THEN

  errorForm "Você não entrou com o E-mail!"

  END IF

  IF ddd = "" THEN

  errorForm "Você não entrou com o DDD!"

  END IF

  IF fone = "" THEN

          errorForm "Você não entrou com o Telefone!"

        END IF

 

'***************************** ENVIA E-MAIL ******************************************************

set mail = Server.CreateObject("Persits.MailSender") - Esta é a linha do erro

mail.from = email

mail.fromname = nome

Mail.AddAddress "faleconosco@athivos.com.br", "ATHIVOS"

mail.subject = "Fale Conosco -- Web Site"

mail.ISHTML = True

Corpo_Email = "Segue abaixo os cometários:<BR><BR>"

Corpo_Email = Corpo_Email & "Nome.: " & nome & "<BR>"

Corpo_Email = Corpo_Email & "E-mail.: " & email & "<BR>"

Corpo_Email = Corpo_Email & "DDD..: " & ddd & "<BR>"

Corpo_Email = Corpo_Email & "Fone.: " & ddd &  " - " & fone & "<BR>"

Corpo_Email = Corpo_Email & "Comentários: " & comentarios & "<BR>"

mail.body = Corpo_Email

Mail.Host = "mail.athivos.com.br"

On Error Resume Next

Mail.Send

If Err = 0 Then

%>

  <td><font color="#666666" size="2" face="Verdana, Arial, Helvetica, sans-serif" class="menu"><b>Seu Contato foi Enviado<br>com Sucesso, Obrigado!<br> Em breve entraremos em contato.</b></td>

<%

Else

%>

  <td><font color="#666666" size="2" face="Verdana, Arial, Helvetica, sans-serif" class="menu"><b>Ocorreu um Erro durante o envio de seu Cadastro<br>Favor Tentar novamente mais tarde !<BR>Erro: <%=Err.Description%></b></font></td>

<%

End IF

'************************* FIM DO ENVIA E-MAIL ***************************************************

%>

</tr>

</table>

  </center>

</div>

</body>

</html>

esta apareçendo isto

Objeto Server error 'ASP 0177 : 800401f3'

Falha em Server.CreateObject

/athivos/conosco_envia.asp, line 59

800401f3

se alguém souber um jeito de melhor de fazer isto estou grato, valeu gente

Link para o comentário
Compartilhar em outros sites

6 respostass a esta questão

Posts Recomendados

  • 0
dark0

dark0

Postado
Postado

você não tem o componente de e-mail instalado em seu servidor.

Link para o comentário
Compartilhar em outros sites
  • 0
cyberalexxx

cyberalexxx

Postado
Postado
aonde eu pego este componente???.....me ajudam não sei nada sobre componentes......valeu!!!

o melhor é ver qual componente o servidor que ira hospedar o site possui, pois não adianta voce conseguir baixar o componente, pois dificilmente voce vai conseguir que o servidor instale o componente pra você.

rode esse script no servidor e veja quais componentes estão instalados:

<%Dim comList(55)

comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
comList(2) = Array( "ActiveFile","ActiveFile.Post" )
comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
comList(5) = Array( "ASP DNS", "AspDNS.Lookup" )
comList(6) = Array( "ASP HTTP","AspHTTP.Conn" )
comList(7) = Array( "ASP Image","AspImage.Image" )
comList(8) = Array( "ASP Mail","SMTPsvg.Mailer" )
comList(9) = Array( "ASP NNTP News", "AspNNTP.Conn" )
comList(10) = Array( "ASP POP 3", "POP3svg.Mailer" )
comList(11) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
comList(12) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
comList(13) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
comList(14) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
comList(15) = Array( "ASP Tear","SOFTWING.ASPtear" )
comList(16) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
comList(17) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
comList(18) = Array( "ASPSoft NT Object","ASPSoft.NT" )
comList(19) = Array( "ASPSoft Upload","ASPSoft.Upload" )
comList(20) = Array( "CDO NTS","CDONTS.NewMail" )
comList(21) = Array( "Chestysoft Image","csImageFile.Manage" )
comList(22) = Array( "Chestysoft Upload","csASPUpload.Process" )
comList(23) = Array( "Dimac JMail","JMail.Message" )
comList(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
comList(25) = Array( "Dundas Mailer","Dundas.Mailer" )
comList(26) = Array( "Dundas Upload","Dundas.Upload.2" )
comlist(27) = Array( "Dundas PieChartServer", "Dundas.ChartServer.2")
comlist(28) = Array( "Dundas 2D Chart", "Dundas.ChartServer2D.1")
comlist(29) = Array( "Dundas 3D Chart", "Dundas.ChartServer")
comList(30) = Array( "Dynu Encrypt","Dynu.Encrypt" )
comList(31) = Array( "Dynu HTTP","Dynu.HTTP" )
comList(32) = Array( "Dynu Mail","Dynu.Email" )
comList(33) = Array( "Dynu Upload","Dynu.Upload" )
comList(34) = Array( "Dynu WhoIs","Dynu.Whois" )
comList(35) = Array( "Easy Mail","EasyMail.SMTP.5" )
comList(36) = Array( "File System Object","Scripting.FileSystemObject" )
comList(37) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
comList(38) = Array( "Last Mod","LastMod.FileObj" )
comList(39) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
comList(40) = Array( "Persits ASP JPEG","Persits.Jpeg" )
comList(41) = Array( "Persits ASPEmail","Persits.MailSender" )
comList(42) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
comList(43) = Array( "Persits File Upload","Persits.Upload.1" )
comList(44) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
comList(45) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
comList(46) = Array( "Image Size", "ImgSize.Check" )
comList(47) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
comList(48) = Array( "Zaks POP3 ", "zakspop3.Server" )
comList(49) = Array( "MS XML ", "MSXML_PROGID2" )
comList(50) = Array( "ASPUpLoad ", "ASPUpLoad.clsUpload" )
comList(51) = Array( "MSXML2 ", "MSXML2.ServerXMLHTTP" )
comList(52) = Array( "AspCrypt ", "AspCrypt.Crypt" )
comList(53) = Array( "AspZip ", "aspZip.EasyZIP" )
comList(54) = Array( "Imagem Glue ", "ImageGlue5.Canvas" )
comList(55) = Array( "Image Effects", "ImageEffects.FX" )

Function TestObject( comIdentity )
 On Error Resume Next
 TestObject = False
 Err.Clear
 Set xTestObj = Server.CreateObject( comIdentity )
 If Err = 0 Then TestObject = True
 Set xTestObj = Nothing
 Err.clear
End Function

Public Function CheckCOM()
 OKCount = 0
 strTxt = "<table border=1 bordercolor=black cellspacing=0 cellpadding=0 align=center width=400>"
 For Idx = LBound( comList ) To UBound( comList )
  Provider = Idx
  strTxt = strTxt & "<tr><td width=200>" & comList(Idx)(0) & "</td>"
  'strTxt = strTxt & ""
  If TestObject( comList(Idx)(1) ) Then
   strTxt = strTxt & "<td align=center><font color=red>Instalado</font></td>"
   OKCount = OKCount + 1
  Else
   strTxt = strTxt & "<td align=center>Não Instalado</td>"
  End If
  strTxt = strTxt & "</tr>"
 Next
 strTxt = strTxt & "</table><p align=center><b>" & OKCount & "</b> de "
 strTxt = strTxt & UBound( comList ) + 1 & " componentes estão avaliados em seu servidor.</p>"
 CheckCOM = strTxt 
End Function

Response.Write( CheckCOM() )%>

Link para o comentário
Compartilhar em outros sites
  • 0
dark0

dark0

Postado
Postado

Amigo, antes de mais nada, você esta rodando este codigo no seu IIS local?

Se estiver, eu aconselho à vc, ou procurar no site do 'fabricante' do componente, alguma versao para download.

Ou, migrar para outro componente, por exemplo, CDONTS, ou JMAIL, ou ....

Já, se estiver rodando direto do seu servidor WEB, aconselho à rodar o script que cyber postou aí, e ver quais componentes ele disponibiliza, e daí, você bolar um codigo baseado em algum dos componentes

Link para o comentário
Compartilhar em outros sites

Participe da discussão

Você pode postar agora e se registrar depois. Se você já tem uma conta, acesse agora para postar com sua conta.

Visitante
Responder esta pergunta...

×   Você colou conteúdo com formatação.   Remover formatação

  Apenas 75 emoticons são permitidos.

×   Seu link foi incorporado automaticamente.   Exibir como um link em vez disso

×   Seu conteúdo anterior foi restaurado.   Limpar Editor

×   Você não pode colar imagens diretamente. Carregar ou inserir imagens do URL.

×
 Share
Ir para lista de Perguntas


  • Estatísticas dos Fóruns

    • Tópicos
      152,3k
    • Posts
      652,3k
×
×
  • Criar Novo...