Internet Explorer, Me Obedeça!

[Denis Bittencourt Muniz]

E aí galera! Uhh! Quanto tempo eu não venho aqui no fórum de VB!

Mas vamos ao que interessa!

Eu preciso que quando a pessoa clicar em algum botão, o internet explorer irá abrir e irá para a URL que eu mandar(defeinirei a url no código)

Isso é OLE?

Pra começar! O que é OLE?

Gostaria que alguém me explicasse, bem definido, o que é OLE! Certo?

Falow em galera!

[ramon]

Bom ai vai um exemplo

Coloque num modulo

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Declare Function RegQueryValueEx Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Any, lpcbData As Long) As Long
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const ERROR_SUCCESS = 0&
Const REG_OPTION_NON_VOLATILE = &O0
Const KEY_ALL_CLASSES As Long = &HF0063
Const KEY_ALL_ACCESS = &H3F
Const REG_SZ As Long = 1

Public Function RegGetString$(hInKey As Long, ByVal subkey$, ByVal valname$)
   Dim RetVal$, hSubKey As Long, dwType As Long, SZ As Long, v$, r As Long
   
   RetVal$ = ""
   
   r = RegOpenKeyEx(hInKey, subkey$, 0, KEY_ALL_CLASSES, hSubKey)
   If r <> ERROR_SUCCESS Then GoTo Quit_Now
   SZ = 256: v$ = String$(SZ, 0)
   r = RegQueryValueEx(hSubKey, valname$, 0, dwType, ByVal v$, SZ)
   If r = ERROR_SUCCESS And dwType = REG_SZ Then
       RetVal$ = Left(v$, SZ - 1)
   Else
       RetVal$ = ""
   End If
   If hInKey = 0 Then r = RegCloseKey(hSubKey)
Quit_Now:
   RegGetString$ = RetVal$

End Function

Public Sub ConnectW3(url$)
On Error GoTo fout_connectw3

   Dim strProgram$, strDDETopic$, strDDEItem$
   Dim intLoaded%

'make on Form1 a invisible textbox named text2
   strProgram = RegGetString(HKEY_CLASSES_ROOT, "http\shell\open\command", "")
   strDDETopic = UCase(RegGetString(HKEY_CLASSES_ROOT, "http\shell\open\ddeexec\Application", "")) & "|" & RegGetString(HKEY_CLASSES_ROOT, "http\shell\open\ddeexec\Topic", "")
   strDDEItem = url$
   With Form1.Text2
       .LinkTopic = strDDETopic
       .LinkItem = strDDEItem & ",," & -1
       .LinkMode = 2
       .LinkRequest
   End With
   Exit Sub
   
fout_connectw3:
   If Err.Number = 282 Then
       If intLoaded = 0 Then
           Shell strProgram, vbNormalFocus
           intLoaded = 1
       ElseIf intLoaded <= 5 Then
           intLoaded = intLoaded + 1
       Else
           Err.Number = vbObjectError + 1
           GoTo fout_connectw3
       End If
       Resume
   ElseIf Err.Number <> 0 Then
       MsgBox "Fatal error while communicating to browser"
       Exit Sub
   End If

End Sub

Coloque um command_button e duas textbox no form e cole este codigo

Private Sub Command1_Click()
  Call ConnectW3(Text1.Text)
End Sub

Private Sub Form_Load()
Text1.Text = "http:\\www.google.com.br"
End Sub

Falou!

[Graymalkin]

Experimente isso aqui:

    Set ie = CreateObject("InternetExplorer.Application")
    ie.Visible = True
    ie.Navigate "http://www.gs.kitbr.com"

Abraços,

Graymalkin

[ramon]

O Graymalkin e seus codigos pequenos mais um que eu vou guardar para a minha coleção

já que o meu é enorme!

[Graymalkin]

O Graymalkin e seus codigos pequenos mais um que eu vou guardar para a minha coleção

já que o meu é enorme!

Hehehe... E tem outro ainda menor (só com uma linha), mas que não é funcional em todas as versões do Windows.

Abraços,

Graymalkin

[Alexandre_Ribeiro]

Ae.. Graymalkin..

seus códigos são muito bons!!!

Gostei deste q abre o iexplorer...

Set ie = CreateObject("InternetExplorer.Application")

ie.Visible = True

ie.navigate "http://www.google.com"

Como faço para fechar o browser q ele abriu ou todos os browser q estiverem abertos?????

Grato,

Alexandre.

[Guest - Paulo -]

Ae.. Graymalkin..

seus códigos são muito bons!!!

Gostei deste q abre o iexplorer...

Set ie = CreateObject("InternetExplorer.Application")

ie.Visible = True

ie.navigate "http://www.google.com"

Como faço para fechar o browser q ele abriu ou todos os browser q estiverem abertos?????

Grato,

Alexandre.

Ae.. Graymalkin..

Usei seu codigo para carregar uma url:

Set ie = CreateObject("InternetExplorer.Application")

ie.Visible = True

ie.navigate "http://www.google.com"

agora preciso dados para dois textbox e efetuar um submit... como faco?

obrigado

[Graymalkin]

Como faço para fechar o browser q ele abriu ou todos os browser q estiverem abertos?????

Você só pode fechar a que você abriu, fazendo:

ie.Quit

Abraços,

Graymalkin

[Graymalkin]

Usei seu codigo para carregar uma url:

Set ie = CreateObject("InternetExplorer.Application")

ie.Visible = True

ie.navigate "http://www.google.com"

agora preciso dados para dois textbox e efetuar um submit... como faco?

Dê uma olhada nos meus posts deste tópico: http://scriptbrasil.com.br/forum/index.php?showtopic=30195

Abraços,

Graymalkin