Ler Noticias Rss Do Uol Em Meu Site (asp) ?

fabiomcg · Fevereiro 4, 2007

Olá galera do forum, agradeço a atenção!

É o seguinte, estou tentando ler as notícias rss do UOL em meu site(em ASP), estou usando um código que achei aqui no forum(segue abaixo), porém ele dá erro quando o XML fonte é do uol.

alguém pode me ajudar?

Agradeço.

Fonte XML: http://rss.vestibular.uol.com.br/ultnot/index.xml

O erro é o seguinte:

Microsoft VBScript runtime error '800a01a8' 

Object required: '[object]' 

/jornal 2007/HTML/Html/lerrss.asp, line 40

Linha 40:

strDescription = objNode2.firstChild.nodevalue

Código que estou usando:

<%
' Script ASP Para leitura de arquivos de RSS.
url = "http://rss.vestibular.uol.com.br/ultnot/index.xml" 'Aqui vai o endereço do arquivo RSS, ou do arquivo "gerador"

' Criando Objeto XML
Set objXML = Server.CreateObject("msxml2.DOMDocument.3.0") 
objXML.async = false 
objXML.setProperty "ServerHTTPRequest", True 

' Não validar o arquivo
objXML.validateOnParse =false' true 

' Retirar espaços 
objXML.preserveWhiteSpace = false 

blnLoaded = objXML.Load(url) 
If Not blnLoaded Then 
    Response.write "Nenhuma notícia na fonte!" 
Else
    set objNodeList = objXML.getElementsByTagName("channel") 

    Set objNodeList = objXML.getElementsByTagName("item") 
    For Each objNode In objNodeList 
        For Each objNode2 In objNode.childNodes 
            Select Case objNode2.nodeName 
            Case "title" 
                strTitle = objNode2.firstChild.nodevalue 
            Case "link" 
                strURL = objNode2.firstChild.nodevalue 
            Case "description" 
                strDescription = objNode2.firstChild.nodevalue  
            End Select 
        Next 

        html = html &"<b><a target=_blank href="& strURL &" class='t11cs' style='text-decoration:none' onMouseOver='window.status=' Clique para ver a notícia completa!';return true;' onMouseOut='window.status='';return true;'><font color='#666666'>"& strTitle &"</a>  ::  </font></b>"
        strTitle = "" 
        strURL = "" 
        strDescription = "" 
    Next 

    html = "<p><marquee scrollamount='1' scrolldelay='2' style='font-family: Tahoma; font-size: 11px' width='700' height='13'>"& html &"</marquee></p>"
    set objNodeList = Nothing 
End if 
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
</head>

<body>
<%
Response.write (html)
%>
</body>
</html>

Bicicleta · Fevereiro 5, 2007

Tá com sorte hoje, hehehehehehe, olha abaixo:

<%
Response.Write "<marquee behavior='scroll' direction='up' width='152' height='150' scrollamount='1' scrolldelay='60' onmouseover=""this.stop()"" onmouseout=""this.start()"">"

url = "http://rss.noticias.uol.com.br/economia/ultnot/index.xml"
Set xml = Server.CreateObject("MSXML2.DOMDocument.3.0")
xml.async = False
xml.SetProperty "ServerHTTPRequest", True
xml.ValidateOnParse = False
xml.PreserveWhiteSpace = False

If Not xml.Load(url) Then
  Response.Write "Nenhuma nticia disponivel no momento."
Else
  Set nodeList = xml.getElementsByTagName("item")
  For Each objNode In nodeList
    For Each objNode2 In objNode.childNodes
      Select Case objNode2.nodeName
        Case "title" : title = objNode2.firstChild.nodevalue
        Case "link"  : link  = objNode2.firstChild.nodevalue
      End Select
    Next
    Response.Write "<a href='"& link &"' target='_blank'>"& title &"</a>" & VbCrLf
    Response.Write "<hr size='1'>" & VbCrLf
  Next
  Set nodeList = Nothing
End If

Set xml = Nothing

Response.Write "</marquee>"
%>

na linha: url = "http://rss.noticias.uol.com.br/economia/ultnot/index.xml", coloque o endereço que você quer...

é pra tá funcionando, fiz pra um site a um tempo, mais num testei, só copiei e postei aqui, se der algum erro posta aí!!!

[]s

fabiomcg · Fevereiro 5, 2007

Muito obrigado Bicicleta,

Perfeito esse seu código, funcionou certinho do jeito que eu queria mesmo..

Agradeço!!

Casca · Julho 20, 2010

Este site é o melhor que eu conheço e tem tudo isso já pronto, e tem todos grandes portais.

http://www.noticiasemseusite.com.br/

Da pra escolher de que portal você quer... (G1, Globo, UOL, Terra, IG, Yahoo, Estadão...) e você escolhe também o assunto... (Economia, Esportes, Tecnologia, Saúde, Entretenimento, Música.....).

Daí é só copiar o bloquinho de código gerado e colar no seu HTML.

Com isso você não precisa se preocupar em atualizar as notícias, pois são pelos proprios portais

Tem que se cadastrar, mas o cadastro é muito simples.

Entrar

Ler Noticias Rss Do Uol Em Meu Site (asp) ?

Pergunta

fabiomcg

Link para o comentário

Compartilhar em outros sites

3 respostass a esta questão

Posts Recomendados

Bicicleta

Link para o comentário

Compartilhar em outros sites

fabiomcg

Link para o comentário

Compartilhar em outros sites

Casca

Link para o comentário

Compartilhar em outros sites

Participe da discussão

Estatísticas dos Fóruns

Navegação

Atividades