Código De Sesão Não Funciona

[ADL]

:) Olá pessoal tudo bem, será que alguém pode me ajudar? É o seguinte estou desenvolvendo uma sessão para saber quantas pessoas estão online mas não aparece quantas pessoas estão online já abri duas páginas juntas para mostrar mas nada veja o código: Esse é o global.asa

<script RUNAT=server LANGUAGE="VBScript">

Sub Application_OnStart

Application("Usuários_Ativos") = 0

End Sub

sub Session_OnStart

Session.timeout = 20

Application.Lock

Application("Usuários_Ativos") = Application("Usuários_Ativos") + 1

Application.UnLock

end sub

sub Session_OnEnd

Session.timeout = 20

Application.Lock

Application("Usuários_Ativos") = Application("Usuários_Ativos") - 1

Application.UnLock

end sub

</script>

e essa é a chamada que está na home será que está certa? Total de visitantes no site : <% = Application("Usuários_Ativos")%>

desde já agradeço pela força!!!!! ADL

Editado Fevereiro 18, 2007 por ADL

[ADL]

:) Olá gostaria de saber onde eu tenho que salvar o arquivo global.asa alguém pode me dizer por favor!!!!!

pois eu não estou conseguindo fazer por favor alguém me ajude!!!!!

Editado Fevereiro 19, 2007 por ADL

[Marcos-rj]

O arquivo global.asa você tem que salvar na raiz do site.

segue um código que uso p/ mostrar os usuarios online.

usuarios_online.asp

<%
Sub LogNewUser
            Dim strUserList
            Dim intUserStart, intUserEnd
            Dim strUser
            Dim strDate

            strUserList = Application("UserList")

        If Instr(1, strUserList, Session.SessionID) > 0 Then
            Application.Lock
            intUserStart = Instr(1, strUserList, Session.SessionID)
            intUserEnd = Instr(intUserStart, strUserList, "|")
            strUser = Mid(strUserList, intUserStart, intUserEnd - intUserStart)
            strUserList = Replace(strUserList, strUser, Session.SessionID & ":" & Now())
            Application("UserList") = strUserList
            Application.UnLock
        Else
            Application.Lock
            Application("ActiveUsers") = CInt(Application("ActiveUsers")) + 1
            Application("UserList") = Application("UserList") & Session.SessionID & ":" & Now() & "|"
            Application.UnLock
        End If
End Sub


'Cleans up the user count so that the script can read the user details from it...

Sub ActiveUserCleanup
Dim ix
Dim intUsers
Dim strUserList
Dim aActiveUsers
Dim intActiveUserCleanupTime
Dim intActiveUserTimeout

intActiveUserCleanupTime = 1 'In minutes, how often should the UserList be cleaned up.
intActiveUserTimeout = 20 'In minutes, how long before a User is considered Inactive and is deleted from UserList

If Application("UserList") = "" Then Exit Sub

If DateDiff("n", Application("ActiveUsersLastCleanup"), Now()) > intActiveUserCleanupTime Then

    Application.Lock
    Application("ActiveUsersLastCleanup") = Now()
    Application.Unlock

    intUsers = 0
    strUserList = Application("UserList")
    strUserList = Left(strUserList, Len(strUserList) - 1)

    aActiveUsers = Split(strUserList, "|")

For ix = 0 To UBound(aActiveUsers)
    If DateDiff("n", Mid(aActiveUsers(ix), Instr(1, aActiveUsers(ix), ":") + 1, Len(aActiveUsers(ix))), Now()) > intActiveUserTimeout Then
        aActiveUsers(ix) = "XXXX"
    Else
        intUsers = intUsers + 1
    End If 
Next

strUserList = Join(aActiveUsers, "|") & "|"
strUserList = Replace(strUserList, "XXXX|", "")

    Application.Lock
    Application("UserList") = strUserList
    Application("ActiveUsers") = intUsers
    Application.UnLock

End If

End Sub


' Shows the amount of users surfing the site

Call LogNewUser()
Call ActiveUserCleanup()

Response.Write Application("ActiveUsers")

%> 

e no local onde você quiser exibir o nº de usuarios coloca:

<!--#include file="usuarios_online.asp"-->

[ADL]

Ok valeu pela dica, quando eu abro duas página mostra dois usuários online quando eu fecho mostra os dois mesmo atualizando o que pode ser?