(Resolvido) Vincular foto no relatório

[Flecha]

Olá,

No forum só achei para Formulário e não sei se é igual.

Tenho uma Tabela com os dados dos funcionários. Um dos campos é o RG.

As fotos estão na pasta c:/Cadastro/fotos e os nomes são os números dos RGs. (12122122.jpg).

Criei um Relatório para imprimir os Nomes, RGs e Endereço, mas quero incluir a foto do funcionário também.

Qual o procedimento para vincular as fotos na saida do Relatório?

Tenho que alterar a estrutura da Tabela acrescentando algum campo ?

Podem me ajudar a construir esse relatório?

Flecha

[MrMALJ]

Fera a lógica é a mesma ok!

Só adapte o codigo para os locais e sessões corretos do seu relatório.

[Flecha]

Valeu,

Copiei um exemplo citado no Forun (Ciclista) e acertei meu Form como o do exemplo e ficou OK.

Agora vou tentar colocar no meu Relatório e retorno se não conseguir.

Obrigado.

Flecha

Editado Novembro 2, 2009 por Flecha

[Leandro Abbade]

Valeu pelo retorno Flecha.

[Flecha]

Olá,

Para quem interessar:

Retirei de um exemplo da net.

Coloquei no meu projet e funcionou, só estou tentando mudar para colocar a foto só de quem é o CHEFE, mas não estou conseguindo. É a parte que esta como comentário nos laços de Ifs do evento ao imprimir.

Na Tabela deve existir o campo Foto (texto) e LocalFoto (texto) esse último irá armazenar o endereço da foto.

Precisa criar um novo módulo para a função FILEEXISTS

Onde a rotina vai verificar se o campo LocalFoto esta vazia ou se o arquivo da foto existe no diretório, em caso negativo ele coloca o arquivo “SemFoto.jpg” no local que não tem nenhuma foto.

No Relatório deverá ser colocado uma Imagem com o nome de Foto e o campo da Tabela LocalFoto.

No evento ao imprimir do Relatório coloquei o código abaixo:

Private Sub Detalhe_Print(Cancel As Integer, PrintCount As Integer)

On Error Resume Next

Dim emptyImg As String

emptyImg = GetPathPart & "SemFoto.jpg"

If IsNull(Me.LocalFoto) Then

Me.Foto.Picture = emptyImg

ElseIf Not FileExists(Me.LocalFoto) Then

Me.Foto.Picture = emptyImg

End If

' If Me.Sit = "CHEFE" Then ' Coloca foto só nos Chefes

Me.Sit.Visible = True

Me.Foto.Picture = Me.LocalFoto

' Else

' Me.Sit.Visible = False

' Me.Foto.Visible = False

' End If

End Sub

Módulo FileExists ...OBS no Meu ficou nomeado como ModFileExits

Option Compare Database

Option Explicit

Public Function FileExists(ByVal strFile As String, Optional bFindFolders As Boolean) As Boolean

'Purpose: Return True if the file exists, even if it is hidden.

'Arguments: strFile: File name to look for. Current directory searched if no path included.

' bFindFolders. If strFile is a folder, FileExists() returns False unless this argument is True.

'Note: Does not look inside subdirectories for the file.

'Author: Allen Browne. http://allenbrowne.com June, 2006.

Dim lngAttributes As Long

'Include read-only files, hidden files, system files.

lngAttributes = (vbReadOnly Or vbHidden Or vbSystem)

If bFindFolders Then

lngAttributes = (lngAttributes Or vbDirectory) 'Include folders as well.

Else

'Strip any trailing slash, so Dir does not look inside the folder.

Do While Right$(strFile, 1) = "\"

strFile = Left$(strFile, Len(strFile) - 1)

Loop

End If

'If Dir() returns something, the file exists.

On Error Resume Next

FileExists = (Len(Dir(strFile, lngAttributes)) > 0)

End Function

Public Function FolderExists(strPath As String) As Boolean

On Error Resume Next

FolderExists = ((GetAttr(strPath) And vbDirectory) = vbDirectory)

End Function

Public Function TrailingSlash(varIn As Variant) As String

If Len(varIn) > 0 Then

If Right(varIn, 1) = "\" Then

TrailingSlash = varIn

Else

TrailingSlash = varIn & "\"

End If

End If

End Function

Public Function GetPathPart() As String

Dim db As DAO.Database

Dim strPath As String

Dim intCounter As Integer

Set db = CurrentDb

strPath = db.Name

db.Close

Set db = Nothing

For intCounter = Len(strPath) To 1 Step -1

If Mid$(strPath, intCounter, 1) = "\" Then

Exit For

End If

Next intCounter

GetPathPart = Left$(strPath, intCounter)

End Function

Flecha

Editado Novembro 2, 2009 por Flecha