LISTBOX(LISTVIEW) COM DUAS CONDIÇÕES DE BUSCA (14 COLUNAS)

[rafaelsetti]

BOA TARDE, ESTOU PRECISANDO CRIAR UM LISTBOX(LISTVIEW) NO VBA COM O REGISTRO NO ACCESS (TABELA AGENDAMENTO) SENDO QUE A BUSCA TEM QUE SE DIRECIONADA PELO CAMPO TEXTBOXFILTRO DO FORMULARIO QUE NA TABELA AGENDAMENTO TERIA QUE SER IGUAL A DATA OU DATA_PROX_AGENDAMENTO SE FOR IGUAL A UM DESSE CAMPOS LISTAR NO LISTBOX OS CAMPOS OS, NOME, DATA. HORA, TELRES,TELCEL,TELCOM,RAMAL,E.MAIL,SERVICO,PROFISSIONAL,DATA_PROX_AGENDAMENTO,HORA_PROX_AGENDAMENTO E OBSERVACAO.

OUTRA DÚVIDA QUE EU TENHO É COMO ABRIR NO VBA UM ARQUIVO PDF E MANDÁ-LO IMPRIMIR DIRETO.

OBRIGADO,

RAFAEL

[Basole]

Olá Rafael seja bem vindo.

Vou começar de traz pra frente, 1º a 2ª dúvida,

Cole em um modulo, em seguida execute a sub testeprint:

Option Explicit
Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
ByVal hwnd As Long, _
ByVal lpOperation As String, _
ByVal lpFile As String, _
ByVal lpParameters As String, _
ByVal lpDirectory As String, _
ByVal nShowCmd As Long) As Long

Public Function PrintThisDoc(formname As Long, FileName As String)
On Error Resume Next
Dim X As Long
X = ShellExecute(formname, "Print", FileName, 0&, 0&, 3)
End Function

Sub TestePrint()
Dim printThis
Dim strDir As String
Dim strFile As String
strDir = "C:\Users\Admin\Desktop" 'AQUI: altere se necessario
strFile = "Nome_do_Arquivo.pdf" 'AQUI: altere p/ o nome do arquivo PDF

printThis = PrintThisDoc(0, strDir & "\" & strFile)

End Sub

[Basole]

Segue abaixo um exemplo da 1ª duvida:

Bom eu não entendi direito se voce vai usar um listbox ou um listview.

então na duvida estou enviando um exemplo para um listview:

Bom eu fiz algumas alterações em cima do que voce passou, mas ainda precisa de algumas alteracoes nos nomes dos campos do BD.

Abx.

Sub Carrega_ListViewXAccess()
' *** não SE ESQUEÇA : Habilite a referencia ActiveX Data object X.XX library
Dim nConn As New ADODB.Connection
Dim banco As ADODB.Recordset
Dim sql As String
Dim nConectar As String
'Endereço e nome do banco de dados * habilite o provedor de acordo c/ sua versao:
nConectar = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & ThisWorkbook.Path & "\base.mdb"
'nConectar = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.Path & "\base.accdb"
nConn.ConnectionString = nConectar
nConn.Open
'CONFIGURANDO O LISTVIEW
Me.ListView1.ListItems.Clear
Me.ListView1.ColumnHeaders.Clear
Me.ListView1.View = lvwReport
Me.ListView1.Gridlines = True

'CRIANDO AS COLUNAS DO LISTVIEW
Me.ListView1.ColumnHeaders.Add , , "CODIGO" 'AQUI: Altere os nomes dos seus cmapos seguindo a ordem
Me.ListView1.ColumnHeaders.Add , , "NOME"
Me.ListView1.ColumnHeaders.Add , , "CARGO"
Me.ListView1.ColumnHeaders.Add , , "SETOR"
Me.ListView1.ColumnHeaders.Add , , "SALARIO"
Me.ListView1.ColumnHeaders.Add , , "DATA DE ADMISSÃO"

'DEFININDO O TAMANHO
Me.ListView1.ColumnHeaders(1).Width = 70 'ajuste de acordo c/ a larg. dos registros
Me.ListView1.ColumnHeaders(2).Width = 200
Me.ListView1.ColumnHeaders(3).Width = 100
Me.ListView1.ColumnHeaders(4).Width = 100
Me.ListView1.ColumnHeaders(5).Width = 60
Me.ListView1.ColumnHeaders(6).Width = 100

'IMPORTAR OS DADOS
sql = "SELECT * FROM [TABELA AGENDAMENTO]"
sql = sql & " WHERE [DATA] = '" & TEXTBOXFILTRO & "'"
sql = sql & " OR [DATA_PROX_AGENDAMENTO]= '" & TEXTBOXFILTRO & "'"

Set banco = New ADODB.Recordset

On Error GoTo erro
banco.Open sql, nConn

Dim nItem As ListItem

'LOOP PARA PREENCHER O LISTVIEW
Do While Not banco.EOF
Set nItem = Me.ListView1.ListItems.Add(, , CStr(banco(0)))
nItem.SubItems(1) = banco(1)
nItem.SubItems(2) = banco(2)
nItem.SubItems(3) = banco(3)
nItem.SubItems(4) = banco(4)
nItem.SubItems(5) = banco(5)
'........................... conplete os campos do bd
banco.MoveNext
Loop

nConn.Close
Set banco = Nothing
Exit Sub
erro:
MsgBox Err.Description
nConn.Close
Set banco = Nothing

End Sub

[rafaelsetti]

OBRIGADO PELA RESPOSTA, FUNCIONOU DIREITINHO O LISTVIEW. ESSE CÓDIGO DO TESTPRINT EU JÁ TINHA TENTADO OUTRA VEZ MAIS NÃO PASSOU,

POSSO TIRAR OUTRA DÚVIDA SEM QUERER ABUSAR DA SUA BOA VONTADE ??? COMO EU INSIRO UMA IMAGEM DENTRO DO SUBITEM DO LISTVIEW É porque TENHO IMAGENS DE PÓS TRATAMENTO, O DO PRÓPRIO PACIENTE ANTES DO TRATAMENTO, E O DO PRONTUÁRIO QUE GOSTARIA DE COLOCÁ-LO. SE TIVER COMO DARIA PARA IMPRIMIR ESSA LISTVIEW COM ESSES DADOS EM PDF ??? OBRIGADO.