Lendo e gravando configurações

[skylopirata]

aee pessoal, bem detalhado :D

Quando nós ouvimos falar em "Registro do Windows" ou "Windows Registry", logo imaginamos que seja algo "de outro mundo"... Mas não é. Na verdade, é muito simples de se usar o Registro do Windows.

Para facilitar na manutenção desses registros, o VB tem 3 funções:

Função(ões)

Ação

SaveSetting

Salvar configurações de programa.

GetSetting, GetAllSettings

Ler configurações de programa.

DeleteSetting

Excluir configurações de programa.

Então, vejamos como funcionam essas funções:

SaveSetting:

============

Salva informações no registro do Windows seguindo alguns parâmetros.

Sintaxe:

SaveSetting [Nome do Aplicativo], [seção], [Chave], [Valor]

Vejamos a descrição dos parâmetros:

[Nome do Aplicativo]: Obrigatório. Nome do aplicativo ou do projeto ao qual se aplica a definição.

[seção] : Obrigatório. Nome da seção em que a definição da chave está sendo salva.

[Chave] : Obrigatório. Nome da definição de chave sendo salva.

[Valor] : Obrigatório. Valor com que será armazenado.

Exemplos:

SaveSetting appname := "MeuProg", _
            section := "Inicialização", _
            key := "Superior", setting := 75
'Ou
SaveSetting "MeuProg", "Inicialização", _
            "Superior", 75

GetSetting: =========== Recupera o valor de uma chave salva no registro do Windows. Sintaxe: GetSetting([Nome do Aplicativo], [seção], [Chave], [Valor Padrão]) Vejamos a descrição dos parâmetros: [Nome do Aplicativo]: Obrigatório. Nome do aplicativo ou do projeto cuja definição de chave é solicitada. [seção] : Obrigatório. Nome da seção onde se encontra a definição de chave. [Chave] : Obrigatório. Nome da definição de chave a ser retornada. [Valor Padrão] : Opcional. Valor a retornar se nenhum valor for definido na definição da chave. Se for omitido, default será assumido como uma string vazia (""). Exemplo:

Dim sRet As String
sRet = GetSetting(appname := "MeuProg", _
                  section := "Inicialização", _
                  key := "Esquerda", _
                  default := "25")

GetAllSettings: =============== Retorna TODAS as chaves e TODOS os valores salvos de determinado programa/seção. Sintaxe: GetAllSettings([Nome do Aplicativo], [seção]) Vejamos a descrição dos parâmetros: [Nome do Aplicativo]: Obrigatório. Nome do aplicativo ou projeto cujas definições de chave são solicitadas. [seção] : Obrigatório. Nome da seção cujas definições de chave são solicitadas. Obs.: GetAllSettings retorna um Variant cujo conteúdo é uma matriz bidimensional de seqüências de caracters contendo todas as definições de chave da seção especificada e seus valores correspondentes. Exemplo:

Dim vRet As Variant, iDef As Integer
vRet = GetAllSettings(appname := "MeuProg", _
                      section := "Inicialização")
For iDef = LBound(vRet, 1) To UBound(vRet, 1)
  Debug.Print vRet(iDef, 0), vRet(iDef, 1)
Next

DeleteSetting: ============== Apaga (deleta) uma ou mais chaves de determinado registro... Sintaxe: DeleteSetting [Nome do Aplicativo], [seção], [Chave] Vejamos a descrição dos parâmetros: [Nome do Aplicativo]: Obrigatório. Nome do aplicativo ou projeto ao qual se aplica a seção ou a definição de chave. [seção] : Obrigatório. Nome da seção da qual a definição da chave está sendo excluída. Se forem fornecidos somente [Nome do Aplicativo] e [seção], a seção especificada será excluída juntamente com todas as definições de chave relacionadas. [Chave] : Opcional. Nome da definição da chave sendo excluída. Exemplo:

'Deletar APENAS uma chave da seção:
DeleteSetting "MeuProg", "Inicialização", _
              "Superior"

'Deletar seção INTEIRA (e TODAS as
'chave da mesma):
DeleteSetting "MeuProg", "Inicialização"

B)

T+ ;)

Editado Abril 25, 2010 por kuroi
Adicionar tag CODE

[Graymalkin]

Ótima explicação skylopirata! :D

Porém, a situação aqui ( http://scriptbrasil.com.br/forum/index.php?showtopic=77693 ) exige escrever chaves específicas do Windows, e não em chaves do programa (que é o que SaveSetting faz).

Seria interessante separar esse seu post para um tópico e deixar ele pendurado para servir como referência para o pessoal. Posso fazer isso?

Abraços,

Graymalkin

[skylopirata]

Sim claro, isso deve ajudar bastante gente, deve ser util para alguém!! :D

T+